I_CustomerMaterialTP

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'ISDCUSTMATTP'
@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [ '_LastChangedByUser' ]
}
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Search.searchable: true

@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.compositionRoot: true

@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.draftEnabled: true
@ObjectModel.entityChangeStateId: 'LastChangeDateTime'

@ObjectModel.writeDraftPersistence: 'ICUSTMATDRAFT'
@ObjectModel.representativeKey:  ['Material','SalesOrganization','DistributionChannel','Customer']
@ObjectModel.semanticKey: ['MaterialForEdit','SalesOrganizationForEdit','DistributionChannelForEdit','CustomerForEdit']
@EndUserText.label: 'Customer Material BO Draft'

define view I_CustomerMaterialTP
  as select from I_CustomerMaterial_2

  association [0..1] to I_SalesOrganization         as _SalesOrganization         on $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel       as _DistributionChannel       on $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_Customer                  as _Customer                  on $projection.Customer = _Customer.Customer
  association [0..1] to I_Material                  as _Material                  on $projection.Material = _Material.Material
  association [0..1] to I_Plant                     as _Plant                     on $projection.Plant = _Plant.Plant
  association [0..1] to I_DeliveryPriority          as _DeliveryPriority          on $projection.DeliveryPriority = _DeliveryPriority.DeliveryPriority
  association [0..1] to I_UnitOfMeasure             as _BaseUnit                  on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_PartialDeliveryItem       as _PartialDeliveryIsAllowed  on $projection.PartialDeliveryIsAllowed = _PartialDeliveryIsAllowed.PartialDeliveryIsAllowed
  association [0..1] to I_CustomerMaterialItemUsage as _CustomerMaterialItemUsage on $projection.CustomerMaterialItemUsage = _CustomerMaterialItemUsage.CustomerMaterialItemUsage
  association [0..*] to I_CustomerMaterialLongTextTP as _CustomerMaterialText     on  $projection.SalesOrganization = _CustomerMaterialText.SalesOrganization 
                                                                                  and $projection.DistributionChannel = _CustomerMaterialText.DistributionChannel
                                                                                  and $projection.Customer = _CustomerMaterialText.Customer
                                                                                  and $projection.Material = _CustomerMaterialText.Material    

  association [0..*] to I_AdditionalCustomerMaterialTP as _AdditionalCustomerMaterial 
    on  $projection.SalesOrganization = _AdditionalCustomerMaterial.SalesOrganization 
    and $projection.DistributionChannel = _AdditionalCustomerMaterial.DistributionChannel
    and $projection.Customer = _AdditionalCustomerMaterial.Customer
    and $projection.Material = _AdditionalCustomerMaterial.Material

  association [0..*] to I_CustMatlAddrDepdntInfoTP as _CustMatlAddrDepdntInfo     on  $projection.SalesOrganization   = _CustMatlAddrDepdntInfo.SalesOrganization
                                                                                  and $projection.DistributionChannel = _CustMatlAddrDepdntInfo.DistributionChannel
                                                                                  and $projection.Customer            = _CustMatlAddrDepdntInfo.Customer
                                                                                  and $projection.Material            = _CustMatlAddrDepdntInfo.Material

  association [0..1] to I_LogisticalRoundingProfile    as _LogisticalRoundingProfile  on  $projection.Plant =  _LogisticalRoundingProfile.Plant
                                                                                      and $projection.RoundingProfile = _LogisticalRoundingProfile.LogisticalRoundingProfile                                                                                     

  //Extensibility

  association [0..1] to E_CustomerMaterial  as _Extension                         on  $projection.Material = _Extension.Material
                                                                                  and $projection.Customer = _Extension.Customer
                                                                                  and $projection.SalesOrganization = _Extension.SalesOrganization
                                                                                  and $projection.DistributionChannel = _Extension.DistributionChannel
                                                                                   
  
{
      @ObjectModel.readOnly:true
  key SalesOrganization,
      @ObjectModel.readOnly:true
  key DistributionChannel,
      @ObjectModel.readOnly:true
  key Customer,
      @ObjectModel.readOnly:true
  key cast (Product as productnumber preserving type) as Material,
  
      _SalesOrganization._Text[1: Language=$session.system_language ].SalesOrganizationName,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      @ObjectModel.text.element:  [ 'SalesOrganizationName' ]
      @ObjectModel.mandatory: true 
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      SalesOrganization            as SalesOrganizationForEdit,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      @ObjectModel.mandatory: true 
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      DistributionChannel          as DistributionChannelForEdit,
--      @ObjectModel.foreignKey.association: '_Customer'
      @ObjectModel.mandatory: true 
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Customer                     as CustomerForEdit,
      @ObjectModel.foreignKey.association: '_Material'
      @ObjectModel.mandatory: true 
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Product                     as MaterialForEdit,
      CustomerMaterialSearchTerm,
      //Customer Material

      MaterialByCustomer,
      MaterialByCustomer           as MaterialByCustomerForEdit,
      @ObjectModel.readOnly: true                                                                        
      @Consumption.filter.hidden: true 
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      _Material._Text[1: Language=$session.system_language ].MaterialName,
      @Semantics.text: true
      MaterialDescriptionByCustomer,
      RoundingProfile,
      //Shipping

      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_DeliveryPriority'
      DeliveryPriority,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MinDeliveryQtyInBaseUnit,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      @ObjectModel.readOnly: true
      BaseUnit,
      //Partial Delivery

      @ObjectModel.foreignKey.association: '_PartialDeliveryIsAllowed'
      PartialDeliveryIsAllowed,
      MaxNmbrOfPartialDelivery,
      UnderdelivTolrtdLmtRatioInPct,
      OverdelivTolrtdLmtRatioInPct,
      UnlimitedOverdeliveryIsAllowed,

      //Control Data

      @ObjectModel.foreignKey.association: '_CustomerMaterialItemUsage'
      CustomerMaterialItemUsage,
      
      //Units of Measure

      SalesUnit,
      SalesQtyToBaseQtyDnmntr,
      SalesQtyToBaseQtyNmrtr,     
      
      LastChangedByUser,
      LastChangeDateTime,// used as a change state ID field

      
      //Associations

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CustomerMaterialText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _AdditionalCustomerMaterial,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CustMatlAddrDepdntInfo,
      _SalesOrganization,
      _DistributionChannel,
      _Customer,
      _Material,
      _Plant,
      _DeliveryPriority,
      _BaseUnit,      
      _PartialDeliveryIsAllowed,
      _CustomerMaterialItemUsage,
      _LastChangedByUser,
      _LogisticalRoundingProfile

}