I_CustRetReleaseStatusText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Returns Order Release Status - Text'
@ObjectModel.representativeKey: 'CustRetReleaseStatus'
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@Analytics.dataExtraction.enabled: true
@Analytics.technicalName: 'ICRTRELSTTXT'
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@Search.searchable: true
define view entity I_CustRetReleaseStatusText
  as select from dd07t

  association to parent I_CustRetReleaseStatus as _ReleaseStatus on $projection.CustRetReleaseStatus = _ReleaseStatus.CustRetReleaseStatus
  association [0..1] to I_Language             as _Language      on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_ReleaseStatus'
    @ObjectModel.text.element: ['CustRetReleaseStatusText']
    key cast( dd07t.domvalue_l as cust_ret_rel_status ) as CustRetReleaseStatus,

    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key cast( dd07t.ddlanguage as spras preserving type ) as Language,
  
    @Analytics.hidden: true
    @Consumption.hidden: true
    dd07t.domvalue_l as DomainValue,

    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #LOW
    ddtext                            as CustRetReleaseStatusText,

    _ReleaseStatus,
    _Language
}

where (domname = 'CUST_RET_REL_STATUS') and (as4local = 'A') and (as4vers  = '0000');