I_CustRetItemProcessStep

@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #COMPOSITE
}
@AccessControl: { 
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['CustomerReturn', 'CustomerReturnItem', 'RetsMgmtProcItmQtySplit', 'RetsMgmtProcessStep', 'ReturnsDocumentType', 'ReturnsDocument', 'ReturnsDocumentItem',
   'ReturnsReferenceDocument', 'ReturnsReferenceDocumentItem'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
   },
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #SQL_DATA_SOURCE],
  modelingPattern: #NONE
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Item Process Steps'
define view entity I_CustRetItemProcessStep
  as select from I_AdvRetsMgmtItmExectdProcStp as ExecutedProcessStep
      inner join I_SalesDocumentBasic          as CustomerReturn  on CustomerReturn.RetsMgmtProcess    = ExecutedProcessStep.RetsMgmtProcess
                                                                 and CustomerReturn.SDDocumentCategory = 'H'
{
      //Key

  key cast(CustomerReturn.SalesDocument as vdm_customer_return preserving type) as CustomerReturn,
  key cast(ExecutedProcessStep.RetsMgmtProcessItem as vdm_customer_return_item preserving type) as CustomerReturnItem,
  key ExecutedProcessStep.RetsMgmtProcItmQtySplit,
  key ExecutedProcessStep.RetsMgmtProcessStep, 

  @ObjectModel.foreignKey.association: '_ReturnsDocumentType'
  key ExecutedProcessStep.ReturnsDocumentType,
  key ExecutedProcessStep.ReturnsDocument,
  key ExecutedProcessStep.ReturnsDocumentItem,
      //Reference Document

  key ExecutedProcessStep.ReturnsReferenceDocument,
  key ExecutedProcessStep.ReturnsReferenceDocumentItem,
      ExecutedProcessStep.ReturnsReferenceDocumentType,
      
      ExecutedProcessStep.RetsMgmtProcess,
      ExecutedProcessStep.RetsMgmtProcessItem,
      
      //Returns Document Status

      ExecutedProcessStep.ReturnsDocumentStatus,
      ExecutedProcessStep.RetsMgmtProcStepExecStatus,
      
      // For Access control

      cast(CustomerReturn.SalesDocumentType as vdm_customer_return_type preserving type) as CustomerReturnType,
      CustomerReturn.OrganizationDivision,
      CustomerReturn.SalesOrganization,
      CustomerReturn.DistributionChannel,
      
      ExecutedProcessStep._ReturnsDocumentType
      
} 

union all

     select from I_AdvncdRetsMgmtItmPlndProcStp  as PlannedProcessStep
      inner join I_SalesDocumentBasic            as CustomerReturn        on CustomerReturn.RetsMgmtProcess    = PlannedProcessStep.RetsMgmtProcess
                                                                         and CustomerReturn.SDDocumentCategory = 'H'
     association [0..1] to I_ReturnsDocumentType as _ReturnsDocumentType  on $projection.ReturnsDocumentType   = _ReturnsDocumentType.ReturnsDocumentType
{
      //Key

  key cast(CustomerReturn.SalesDocument as vdm_customer_return preserving type) as CustomerReturn,
  key cast(PlannedProcessStep.RetsMgmtProcessItem as vdm_customer_return_item preserving type) as CustomerReturnItem,
  key PlannedProcessStep.RetsMgmtProcItmQtySplit,
  key PlannedProcessStep.RetsMgmtProcessStep, 
  key cast ( '' as msr_doc_type ) as ReturnsDocumentType,
  key cast ( '' as msr_doc_nr )   as ReturnsDocument,
  key cast ( '0000000000' as msr_doc_item preserving type ) as ReturnsDocumentItem,
      //Reference Document

  key PlannedProcessStep.ReturnsReferenceDocument,
  key PlannedProcessStep.ReturnsReferenceDocumentItem,
      PlannedProcessStep.ReturnsReferenceDocumentType,
      
      PlannedProcessStep.RetsMgmtProcess,
      PlannedProcessStep.RetsMgmtProcessItem,
      
      //Returns Document Status

      cast ( '' as msr_doc_status )      as ReturnsDocumentStatus,
      
      cast ( case when PlannedProcessStep.RetsMgmtProcStepExecStatus = '2' 
         then
          '2' -- ->'with errors'
         else
          '' -- ->'not yet created'
        end as msr_exec_step_status ) as RetsMgmtProcStepExecStatus,
           
      // For Access control

      cast(CustomerReturn.SalesDocumentType as vdm_customer_return_type preserving type) as CustomerReturnType,
      CustomerReturn.OrganizationDivision,
      CustomerReturn.SalesOrganization,
      CustomerReturn.DistributionChannel,
      
      _ReturnsDocumentType
      
}