I_CostComponentHierarchyNode

@EndUserText.label: 'Cost Breakdown Hierarchy Node'
@VDM.viewType: #BASIC
@Hierarchy.parentChild:
[{ recurse:          {   parent: ['ParentNode'],   child:  ['HierarchyNode']  },
  siblingsOrder:    [{   by: 'HierarchyNodeSequence' }],
  directory:        '_Hierarchy'
  }]
@Metadata.ignorePropagatedAnnotations:true
@AccessControl.authorizationCheck: #MANDATORY
//@ObjectModel.representativeKey: 'HierarchyNode'

@ObjectModel.modelingPattern: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET,#ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE , #EXTRACTION_DATA_SOURCE ]

@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #S},
  dataCategory: #HIERARCHY
}
@Analytics: { dataExtraction.enabled: true }
@ObjectModel.sapObjectNodeType.name:'CostComponentHierarchyNode'

define view entity I_CostComponentHierarchyNode
  as select from hrrp_node_n

  association [0..*] to I_CostComponentHierNodeTxt as _Text                   on  $projection.CostComponentHierarchy = _Text.CostComponentHierarchy
                                                                              and $projection.HierarchyNode          = _Text.HierarchyNode
                                                                              and $projection.CostBreakdownComponent = ''

  association [0..1] to I_CostBreakdownComponent   as _CostBreakdownComponent on  $projection.CostBreakdownStructure = _CostBreakdownComponent.CostBreakdownStructure
                                                                              and $projection.CostBreakdownComponent = _CostBreakdownComponent.CostBreakdownComponent

  association [1..1] to I_CostComponentHierarchy   as _Hierarchy              on  $projection.CostComponentHierarchy = _Hierarchy.CostComponentHierarchy
                                                                              and $projection.ValidityEndDate        = _Hierarchy.ValidityEndDate
  association [0..1] to I_CostBreakdownStructure   as _CostBreakdownStructure on  $projection.CostBreakdownStructure = _CostBreakdownStructure.CostBreakdownStructure

{
        @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
        @ObjectModel.foreignKey.association: '_Hierarchy'
  key   cast(hrrp_node_n.hryid as fucb_cost_comp_hierid preserving type ) as CostComponentHierarchy,
        @ObjectModel.text.association: '_Text'
  key   hrrp_node_n.hrynode                                               as HierarchyNode,
        @Semantics.businessDate.to: true
        @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
  key   cast(hrrp_node_n.hryvalto as fis_datbi preserving type )          as ValidityEndDate,
        @Semantics.businessDate.from: true
        cast(hrrp_node_n.hryvalfrom as fis_datab preserving type )        as ValidityStartDate,
        hrrp_node_n.parnode                                               as ParentNode,
        @ObjectModel.foreignKey.association: '_CostBreakdownComponent'
        hrrp_node_n.cost_component                                        as CostBreakdownComponent,
        @ObjectModel.foreignKey.association: '_CostBreakdownStructure' //Inserted by VDM CDS Suite Plugin

        hrrp_node_n.cost_comp_struc                                       as CostBreakdownStructure,

        hrrp_node_n.hryseqnbr                                             as HierarchyNodeSequence,
        hrrp_node_n.hrylevel                                              as HierarchyNodeLevel,
        hrrp_node_n.nodetype                                              as NodeType,
        hrrp_node_n.nodevalue                                             as HierarchyNodeVal,

        _Text,
        _Hierarchy,
        _CostBreakdownComponent,
        _CostBreakdownStructure

}
where
      hrrp_node_n.nodetype <> 'D'
  and hrrp_node_n.hrytyp   =  'CB01';