I_CostCenterActivityTypeTP

@AbapCatalog: {
  sqlViewName: 'ICCACTTYPTP',
  compiler.compareFilter: true,
  preserveKey: true
}

@VDM.viewType: #TRANSACTIONAL

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE

// BOPF

@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.compositionRoot: true

// Draft Related Annotations

@ObjectModel.draftEnabled: true
@ObjectModel.draft.sharing: #PUBLIC
@ObjectModel.draft.concurrentEditing: true

@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.semanticKey: [ 'ControllingArea', 'CostCtrActivityType', 'ValidityEndDate' ]
@ObjectModel.writeDraftPersistence: 'CSLA_DRAFT'

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'

//@ObjectModel.entityChangeStateId: 'ETag'


@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@EndUserText.label: 'Cost Center Activity Type'

define view I_CostCenterActivityTypeTP
  as select from P_CostCenterActivityTypeTP

  association [1..*] to I_CostCenterActivityTypeTextTP as _CostCenterActivityTypeTextTP on  $projection.ControllingArea     = _CostCenterActivityTypeTextTP.ControllingArea
                                                                                        and $projection.CostCtrActivityType = _CostCenterActivityTypeTextTP.CostCtrActivityType
                                                                                        and $projection.ValidityEndDate     = _CostCenterActivityTypeTextTP.ValidityEndDate

{
  key ControllingArea,
  key CostCtrActivityType,
  key ValidityEndDate,
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea                                                                                 as ControllingAreaForEdit,
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.editableFieldFor: 'CostCtrActivityType'
      CostCtrActivityType                                                                             as CostCtrActivityTypeForEdit,
      @ObjectModel.mandatory: true
      @ObjectModel.editableFieldFor: 'ValidityEndDate'
      ValidityEndDate                                                                                 as ValidityEndDateForEdit,
      @ObjectModel.mandatory: true
      ValidityStartDate,
      @ObjectModel.mandatory: true
      CostCtrActivityTypeQtyUnit,
      @ObjectModel.mandatory: true
      CostCtrActivityTypeCategory,
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      AllocationCostElement,
      CostCtrActivityTypeOutpQtyUnit,
      @ObjectModel.readOnly: true
      CreationDate,
      @ObjectModel.readOnly: true
      EnteredByUser,
      ActlPostgCostCenterActyTypeCat,
      OutputQuantityFactor,
      ActivityTypeIsBlocked,
      FixedCostIsPredistributed,
      PriceAllocationMethod,
      PeriodPriceIsAverage,
      @ObjectModel.readOnly: true
      cast( 'X' as flag preserving type ) as ActyTypeDfltIndicatorIsHidden,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      ActualPriceAllocationMethod,
      ActualQuantityIsSetManually,
      PlanQuantityIsSetManually,
      @ObjectModel.mandatory: true
      CostCtrActivityTypeValidCat,
      @ObjectModel.mandatory: true
      cast ( CostCtrActivityTypeName as ktext preserving type ) as CostCtrActivityTypeName,
      cast ( CostCtrActivityTypeDesc as kltxt preserving type ) as CostCtrActivityTypeDesc,
      ChartOfAccounts,
      @ObjectModel.readOnly: true
      cast( concat(ValidityStartDate, concat('-',ValidityEndDate)) as activitytypevalidityperiodtext) as ActivityTypeValidityPeriodText,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      cast( concat(ControllingArea, CostCtrActivityType) as cdobjectv )                               as ChangeDocObject,
      
//      cast(CONCAT ( CONCAT( ControllingArea, CostCtrActivityType), ValidityEndDate ) as hash160) as ETag,



      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _CostCenterActivityTypeTextTP,
      _Text,
      _ControllingArea,
      _CostCenterCategory,
      _CostCtrActivityTypeCategory,
      _UnitOfMeasure

}