I_CostAnalysisResourceText

 @AbapCatalog.entityBuffer.definitionAllowed: false
 @EndUserText.label: 'Cost Analysis Resource - Text'
@Analytics: {dataExtraction.enabled: true}
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { dataCategory: #TEXT,
                representativeKey: 'CostAnalysisResource',
                usageType.sizeCategory: #M,
                usageType.dataClass:  #MASTER,
                usageType.serviceQuality: #A,
                supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE, #SEARCHABLE_ENTITY],
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT }
@Analytics.technicalName: 'IFICOANLYSRESRCT'                   
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true

define view entity I_CostAnalysisResourceText
  as select from cskv
  left outer to one join cskr as _md on cskv.resrc = _md.resrc
                                     and cskv.kokrs = _md.kokrs
                                     and cskv.datbi = _md.datbi
  association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_Language        as _Language        on $projection.Language = _Language.Language
{
      @ObjectModel.text.element: ['CostAnalysisResourceDesc', 'CostAnalysisResourceName']
  key cast( cskv.resrc as fis_co_resource preserving type ) as CostAnalysisResource,

      @ObjectModel.foreignKey.association: '_ControllingArea'
  key cast( cskv.kokrs as fis_kokrs preserving type )       as ControllingArea,

      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cskv.spras                                                 as Language,

      @Semantics.businessDate.to: true
  key cast( cskv.datbi as fis_datbi preserving type )       as ValidityEndDate,

      @Semantics.businessDate.from: true
      cast( _md.datab as fis_datab preserving type )            as ValidityStartDate,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      cast( cskv.ktext as fis_co_resrc_name preserving type )    as CostAnalysisResourceName,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      cast( cskv.ltext as fis_co_resrc_desc preserving type )    as CostAnalysisResourceDesc,

      _ControllingArea,
      _Language
}