I_ContractAccountPartnerUI

DDL: I_CONTRACTACCOUNTPARTNERUI Type: view_entity COMPOSITE Package: ODATA_O2C_FICA_CONTRACCT_MAN

Contract Account Partner UI Enhancements

I_ContractAccountPartnerUI is a Composite CDS View that provides data about "Contract Account Partner UI Enhancements" in SAP S/4HANA. It reads from 1 data source (I_ContractAccountPartner) and exposes 26 fields with key fields ContractAccount, BusinessPartner. It has 4 associations to related views. Part of development package ODATA_O2C_FICA_CONTRACCT_MAN.

1 data source(s) 26 fields

Data Sources (1)

SourceAliasJoin Type
I_ContractAccountPartner I_ContractAccountPartner from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_CAContractPartnerAddress _Address $projection.BusinessPartner = _Address.BusinessPartner and $projection.AddressID = _Address.AddressNumber
[0..1] I_WithholdingTaxCode _IncgPaytWithholdingTaxCode $projection.CAStandardCompanyCodeCountry = _IncgPaytWithholdingTaxCode.Country and $projection.IncgPaytWithholdingTaxCode = _IncgPaytWithholdingTaxCode.WithholdingTaxCode
[0..1] I_WithholdingTaxCode _OutgPaytWithholdingTaxCode $projection.CAStandardCompanyCodeCountry = _OutgPaytWithholdingTaxCode.Country and $projection.OutgPaytWithholdingTaxCode = _OutgPaytWithholdingTaxCode.WithholdingTaxCode
[1..1] I_CALastDayOfBillingPeriod _CALastDayOfBillingPeriod $projection.CALastDayOfBillingPeriod = _CALastDayOfBillingPeriod.CALastDayOfBillingPeriod

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Contract Account Partner UI Enhancements view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.representativeKey BusinessPartner view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #COMPOSITE view

Fields (26)

KeyFieldSource TableSource FieldDescription
KEY ContractAccount ContractAccount
KEY BusinessPartner BusinessPartner
ContractAccountCategory _ContrAcc ContractAccountCategory
ContractAccountCategoryName
CompanyCodeName _CompCode CompanyCodeName
BusinessPartnerFullName _BusinessPartner BusinessPartnerFullName
StreetName
HouseNumber
PostalCode
CityName
Country
CountryName
AddressID AddressID
CABillgCycle CABillgCycle
CALastDayOfBillingPeriod CALastDayOfBillingPeriod
IncgPaytWithholdingTaxCode IncgPaytWithholdingTaxCode
OutgPaytWithholdingTaxCode OutgPaytWithholdingTaxCode
CAAuthorizationGroup CAAuthorizationGroup
_Address _Address
_BillgCycle _BillgCycle
_BusinessPartner _BusinessPartner
_CALastDayOfBillingPeriod _CALastDayOfBillingPeriod
_ContrAcc _ContrAcc
_CompCode _CompCode
_IncgPaytWithholdingTaxCode _IncgPaytWithholdingTaxCode
_OutgPaytWithholdingTaxCode _OutgPaytWithholdingTaxCode 
@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] } }

@EndUserText.label: 'Contract Account Partner UI Enhancements'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { representativeKey: 'BusinessPartner',
                usageType:{ dataClass: #TRANSACTIONAL,
                            serviceQuality: #C,
                            sizeCategory: #L } }

@VDM.viewType: #COMPOSITE

define view entity I_ContractAccountPartnerUI
  as select from I_ContractAccountPartner

  association [0..1] to I_CAContractPartnerAddress as _Address                    on  $projection.BusinessPartner = _Address.BusinessPartner
                                                                                  and $projection.AddressID       = _Address.AddressNumber
  association [0..1] to I_WithholdingTaxCode       as _IncgPaytWithholdingTaxCode on  $projection.CAStandardCompanyCodeCountry = _IncgPaytWithholdingTaxCode.Country
                                                                                  and $projection.IncgPaytWithholdingTaxCode   = _IncgPaytWithholdingTaxCode.WithholdingTaxCode
  association [0..1] to I_WithholdingTaxCode       as _OutgPaytWithholdingTaxCode on  $projection.CAStandardCompanyCodeCountry = _OutgPaytWithholdingTaxCode.Country
                                                                                  and $projection.OutgPaytWithholdingTaxCode   = _OutgPaytWithholdingTaxCode.WithholdingTaxCode
  association [1..1] to I_CALastDayOfBillingPeriod as _CALastDayOfBillingPeriod   on  $projection.CALastDayOfBillingPeriod = _CALastDayOfBillingPeriod.CALastDayOfBillingPeriod

{
      @ObjectModel.foreignKey.association: '_ContrAcc'
  key ContractAccount,
  key BusinessPartner,

      _ContrAcc.ContractAccountCategory,
      _ContrAcc._Category._Text[1:Language = $session.system_language].ContractAccountCategoryName,

      _CompCode.CompanyCodeName,
      _CompCode.Country                                                                                                                                as CAStandardCompanyCodeCountry,

      _BusinessPartner.BusinessPartnerFullName,
      cast( concat_with_space(_BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName,
                              _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber, 1) as adress_gfn_kk preserving type ) as AddressLine1,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.CityName,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.Country,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation._Country._Text[1: Language=$session.system_language].CountryName,


      //Address of Business Partner

      AddressID,

      CABillgCycle,
      CALastDayOfBillingPeriod,
      case when CALastDayOfBillingPeriod is not initial
        then _CALastDayOfBillingPeriod._CALastDayOfBillingPeriodText[1:Language = $session.system_language].CALastDayOfBillingPeriodText
        else _BillgCycle._CALastDayOfBillingPeriod._CALastDayOfBillingPeriodText[1:Language = $session.system_language].CALastDayOfBillingPeriodText
      end                                                                                                                                              as CALastDayOfBillingPeriodText,

      IncgPaytWithholdingTaxCode,
      OutgPaytWithholdingTaxCode,

      // for authorization check

      CAStandardCompanyCode,
      CAAuthorizationGroup,

      /* Associations */
      _Address,
      _BillgCycle,
      _BusinessPartner,
      _CALastDayOfBillingPeriod,
      _ContrAcc,
      _CompCode,
      _IncgPaytWithholdingTaxCode,
      _OutgPaytWithholdingTaxCode
}

Learn More