I_ConsCharAttributeText

DDL: I_CONSCHARATTRIBUTETEXT SQL: ICNSCHARATTRT Type: view BASIC Package: FIN_CS_MASTER_DATA_ENHCD

Charcteristics Attribute Text

I_ConsCharAttributeText is a Basic CDS View that provides data about "Charcteristics Attribute Text" in SAP S/4HANA. It reads from 2 data sources (dd04t, I_CnsldtnAllCharsAttribute) and exposes 9 fields with key fields ConsolidationAttributeName, ConsolidationMDCharcName, Language. It has 3 associations to related views. Part of development package FIN_CS_MASTER_DATA_ENHCD.

2 data source(s) 9 fields

Data Sources (2)

SourceAliasJoin Type
dd04t DD inner
I_CnsldtnAllCharsAttribute I_CnsldtnAllCharsAttribute from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language
[0..1] I_CnsldtnAllCharsAttribute _CnsldtnAllCharsAttribute $projection.ConsolidationAttributeName = _CnsldtnAllCharsAttribute.ConsolidationAttributeName and $projection.ConsolidationMDCharcName = _CnsldtnAllCharsAttribute.ConsolidationMDCharcName
[0..*] I_CnsldtnAllChars _CnsldtnAllChars $projection.ConsolidationMDCharcName = _CnsldtnAllChars.AdditionalCharcFieldName

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName ICNSCHARATTRT view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #TEXT view
VDM.viewType #BASIC view
EndUserText.label Charcteristics Attribute Text view
Search.searchable true view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY ConsolidationAttributeName ConsolidationAttributeName
KEY ConsolidationMDCharcName ConsolidationMDCharcName
KEY Language dd04t ddlanguage
AttributeDataElement rollname
ConsolidationAttributeFldText ddtext
ConsolidationAttributeLongText scrtext_l
_Language _Language
_CnsldtnAllCharsAttribute _CnsldtnAllCharsAttribute
_CnsldtnAllChars _CnsldtnAllChars 
@AbapCatalog.sqlViewName: 'ICNSCHARATTRT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #L
}
@ObjectModel.dataCategory: #TEXT

@VDM.viewType: #BASIC
@EndUserText.label: 'Charcteristics Attribute Text'

@Search.searchable: true

define view I_ConsCharAttributeText
  as select from I_CnsldtnAllCharsAttribute

    inner join   dd04t as DD on I_CnsldtnAllCharsAttribute.AttributeDataElement = DD.rollname

  association [0..1] to I_Language                 as _Language                 on  $projection.Language = _Language.Language

  association [0..1] to I_CnsldtnAllCharsAttribute as _CnsldtnAllCharsAttribute on  $projection.ConsolidationAttributeName = _CnsldtnAllCharsAttribute.ConsolidationAttributeName
                                                                                and $projection.ConsolidationMDCharcName   = _CnsldtnAllCharsAttribute.ConsolidationMDCharcName

  association [0..*] to I_CnsldtnAllChars          as _CnsldtnAllChars          on  $projection.ConsolidationMDCharcName = _CnsldtnAllChars.AdditionalCharcFieldName
{

       @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}
  key  ConsolidationAttributeName,

       @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}
  key  ConsolidationMDCharcName,

       @Semantics.language
  key  DD.ddlanguage as Language,

       @Consumption.hidden: true
       rollname      as AttributeDataElement,

       //@Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}

       @Semantics.text
       ddtext        as ConsolidationAttributeFldText,

       @Semantics.text
       cast (
        case
          when scrtext_m is not initial
          then scrtext_m
          else scrtext_s end as scrtext_m ) as ConsolidationAttributeMedText,

       @Semantics.text
       scrtext_l     as ConsolidationAttributeLongText,


       _Language,
       _CnsldtnAllCharsAttribute,
       _CnsldtnAllChars
}
where
  DD.as4local = 'A'

Learn More