I_CommodityOrderRequestVH

@AbapCatalog.sqlViewName              : 'ICMMDTYORDVH'
@AbapCatalog.compiler.compareFilter   : true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck     : #CHECK
@AccessControl.personalData.blocking  : #REQUIRED
@EndUserText.label                    : 'Value Help View for Order Request'
@VDM.viewType                         : #COMPOSITE
@ClientHandling.algorithm             : #SESSION_VARIABLE
@ObjectModel.representativeKey        : 'CommodityOrderRequest'
@ObjectModel.usageType                : { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }
@Metadata.ignorePropagatedAnnotations :true
@Search.searchable: true
@Consumption.ranked: true

define view I_CommodityOrderRequestVH
  as select from    I_CommodityOrderRequest  as CommodityOrderRequest

  -- To get Order Request Kind, Counterparty Info based on Commodity Order Request Type
    left outer join I_CmmdtyOrderRequestType as CmmdtyOrderReqType     on CmmdtyOrderReqType.CmmdtyOrderRequestType = CommodityOrderRequest.CmmdtyOrderRequestType

  -- Association to get text for Commodity Order Request Status
    left outer join I_CmmdtyOrdReqStatusText as CmmdtyOrdReqStatusText on CmmdtyOrdReqStatusText.CmmdtyOrderRequestStatus = CommodityOrderRequest.CmmdtyOrderRequestStatus

  -- Association to get text for Commodity Order Request Source
    left outer join I_CmmdtyOrdReqSourceText as CmmdtyOrdReqSourceText on CmmdtyOrdReqSourceText.CmmdtyOrderRequestSource = CommodityOrderRequest.CmmdtyOrderRequestSource

  -- Association to get text for Commodity Order Request Reason
    left outer join I_CmmdtyOrdReqReasonText as CmmdtyOrdReqReasonText on CmmdtyOrdReqReasonText.CmmdtyOrderRequestReason = CommodityOrderRequest.CmmdtyOrderRequestReason

  -- Association to get Future ID Value Help
  association [0..*] to I_CommodityOrderLeg as _CommodityOrderLeg on CommodityOrderRequest.CommodityOrderRequestUUID = _CommodityOrderLeg.CommodityOrderRequestUUID

{
@Search:{defaultSearchElement:true,ranking:#HIGH,fuzzinessThreshold:0.7}
  key CommodityOrderRequest.CommodityOrderRequest                                                 as      CommodityOrderRequest,
@Search:{defaultSearchElement:true,ranking:#LOW,fuzzinessThreshold:0.7}
      CommodityOrderRequest.CmmdtyOrderRequestType                                                as      CmmdtyOrderRequestType,
      cast(CmmdtyOrderReqType.CmmdtyOrderRequestTypeText
                  as cmmfdor_ordertypetext preserving type )                                      as      CmmdtyOrderRequestTypeText,

      CommodityOrderRequest.CmmdtyOrderRequestReason                                              as      CmmdtyOrderRequestReason,
      cast( CmmdtyOrdReqReasonText.CmmdtyOrderRequestReasonText
                    as cmmfdor_ordreqreasontext preserving type )                                 as      CmmdtyOrderRequestReasonText,

      CommodityOrderRequest.CmmdtyOrderRequestStatus                                              as      CmmdtyOrderRequestStatus,
      cast( CmmdtyOrdReqStatusText.CmmdtyOrderRequestStatusText
                    as cmmfdor_ordreqstatusdesc preserving type )                                 as      CmmdtyOrderRequestStatusText,

      CommodityOrderRequest.CmmdtyOrderRequestSource                                              as      CmmdtyOrderRequestSource,
      cast( CmmdtyOrdReqSourceText.CmmdtyOrderRequestSourceText
                    as cmmfdor_cmmdtyordreqsourcetext preserving type )                           as      CmmdtyOrderRequestSourceText,

      CmmdtyOrderReqType.CmmdtyOrderRequestKind                                                   as      CmmdtyOrderRequestKind,
      cast(CmmdtyOrderReqType.CmmdtyOrderRequestKindText
                    as cmmfdor_cmmdtyordreqkindtext preserving type )                             as      CmmdtyOrderRequestKindText,

      CommodityOrderRequest.CommoditySubAccount                                                   as      CommoditySubAccount,
      cast(CommodityOrderRequest.CommoditySubAccountName
                    as cmmfdor_assignedsubaccountname preserving type )                           as      CommoditySubAccountName,

      _CommodityOrderLeg.CmmdtyOrderRequestFlowType                                               as      CmmdtyOrderRequestFlowType,
      cast(_CommodityOrderLeg.CmmdtyDerivativeFlowTypeText
                    as cmmfdor_ordflowtypedescription preserving type )                           as      CmmdtyDerivativeFlowTypeText,

      _CommodityOrderLeg.CommodityDerivativeFuture                                                as      CommodityDerivativeFuture,
      cast(_CommodityOrderLeg.CommodityDerivativeFutureName
                    as cmmfdor_futurename preserving type )                                       as      CommodityDerivativeFutureName,

      _CommodityOrderLeg.Commodity                                                                as      Commodity,
      cast(_CommodityOrderLeg.CommodityName
                    as cmmfdor_exchangecommodityname preserving type )                            as      CommodityName

}