I_CommodityHedgeTransaction

@AbapCatalog.sqlViewName: 'ICMMHDGFITRANS'
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Financial Transaction Details'
@VDM.viewType: #BASIC
define view I_CommodityHedgeTransaction
  as select from vtbfha as Transaction
{
  key     Transaction.bukrs                  as FinTransactionCompanyCode,
  key     Transaction.rfha                   as FinTransactionDealIdentifier,
          Transaction.sanlf                  as FinTransactionProductCategory,
          Transaction.objnr                  as FinTransactionObjectNumber,
          Transaction.sgsart                 as FinTransactionProductType,
          Transaction.rfhazul                as FinancialInstrumentActivity,
          Transaction.skalid                 as FinTransFactoryCalendar1,
          Transaction.skalid2                as FinTransFactoryCalendar2,
          Transaction.saktiv                 as FinancialInstrumentStatus,
          Transaction.kontrh                 as FinTransactionCounterparty,
          Transaction.sgsart                 as FinancialInstrumentProductType,
          Transaction.sfhaart                as FinancialInstrTransactionType,
          Transaction.hedge_book             as FinancialTransactionHedgeBook,
          Transaction.rportb                 as FinancialTransactionPortfolio,
          Transaction.rcomvalcl2             as FinTransGeneralValuationClass,
          Transaction.zuond                  as FinancialTransactionAssignment,
          Transaction.refer                  as FinTransInternalReference,
          Transaction.merkm                  as FinTransactionCharacteristic,
          Transaction.dblfz                  as ContractStartDate,
          Transaction.delfz                  as ContractEndDate,
          Transaction.rfhazul                as OptionUnderlyingActivity,
          Transaction.hedge_request_id       as HedgeRequestIdentifier,
          Transaction.hedge_specification_id as CmmdtyHdgSpecificationID,
          Transaction.hedge_spec_order_id    as CmmdtyHdgSpecQuotaOrderID,
          Transaction.hedge_class            as HdggArHedgingClassification,
          Transaction.behalf_of_company      as FinTransOnBehalfOfCompany,
          case //for the FX Trade set flow

          when  Transaction.sanlf = '600'
          then '0002'
          else '0001'
          end                                as FinTransFlowNumber
}
where
  Transaction.saktiv = '0' //only active trade