I_CollectionsStrategy

@AbapCatalog: { sqlViewName: 'ICOLLSSTRAT',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData:       { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Strategy' }
@VDM: { viewType: #BASIC,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #CUSTOMIZING },
                semanticKey: [ 'CollectionStrategy' ],
                representativeKey: 'CollectionStrategy' }

define view I_CollectionsStrategy
  as select from udm_strategy

  // VDM Associations

  // Currency

  association [0..1] to I_Currency                as _Currency                on $projection.CollStrgyCurrency = _Currency.Currency

  // Collections Strategy Text

  association [0..*] to I_CollectionsStrategyText as _CollectionsStrategyText on $projection.CollectionStrategy = _CollectionsStrategyText.CollectionStrategy

{

      // VDM Fields

  key coll_strategy                                                            as CollectionStrategy,

      @Semantics: { currencyCode: true }
      @ObjectModel: { foreignKey: { association: '_Currency' } }
      currency                                                                 as CollStrgyCurrency,

      max_valuation                                                            as CollStrgyMaxValuation,
      cast(x_cash_disc as fin_mng_colstr_cash_disc_dline preserving type )     as CollDuDteCshDiscIsConsidered,
      cast(no_of_days as fin_mng_colstr_day_before_due preserving type )       as CollStrgyNmbrDaysBeforeDueDate,
      cast(dunn_days as fin_mng_colstr_dunn_grace_days preserving type )       as CollStrgyTolDaysAfterDunn,
      cast(x_legal_dunn as fin_mng_colstr_flag_legal_dunn preserving type )    as CollItmWthLglDunProcedIsExcl,
      overdue_period1                                                          as CollStrgyOverduePeriod1,
      cast(overdue_period2 as fin_mng_colstr_overdue_period2 preserving type ) as CollStrgyOverduePeriod2,
      cast(overdue_period3 as fin_mng_colstr_overdue_period3 preserving type ) as CollStrgyOverduePeriod3,
      cast(overdue_period4 as fin_mng_colstr_overdue_period4 preserving type ) as CollStrgyOverduePeriod4,
      due_period1                                                              as CollStrgyDueDatePeriod1,
      cast(due_period2 as fin_mng_colstr_due_period2 preserving type )         as CollStrgyDueDatePeriod2,
      cast(due_period3 as fin_mng_colstr_due_period3 preserving type )         as CollStrgyDueDatePeriod3,
      cast(due_period4 as fin_mng_colstr_due_period4 preserving type )         as CollStrgyDueDatePeriod4,

      @Semantics: { user: { createdBy: true } }
      created_by                                                               as CollStrgyCreatedBy,

      @Semantics: { systemDateTime: { createdAt: true } }
      cast( created_at as coll_pr_creation_date_time preserving type )         as CollStrgyCreatedOn,

      @Semantics: { user: { lastChangedBy: true } }
      changed_by                                                               as CollStrgyLastChangedBy,

      @Semantics: { systemDateTime: { lastChangedAt: true } }
      cast( changed_at as coll_pr_changed_at preserving type )                 as CollStrgyLastChangedOn,

      // Exposed Associations

      _Currency,
      _CollectionsStrategyText

}