I_CollectionsContactDraft

@AbapCatalog: { sqlViewName: 'ICOLLSCNTDR',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #NOT_REQUIRED,
                  privilegedAssociations: [ '_DraftAdministrativeData' ],
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Contacts Drafts' }
@VDM: { viewType: #BASIC,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                semanticKey: ['RelationshipNumber', 'BusinessPartnerCompany', 'BusinessPartnerPerson', 'CollectionSegment' ],
                representativeKey: 'DraftUUID' }

define root view I_CollectionsContactDraft
  as select from collcontdra

  // VDM Associations

  // Business Partner Company

  association [1..1] to I_BusinessPartner         as _BusinessPartnerCompany  on  $projection.BusinessPartnerCompany = _BusinessPartnerCompany.BusinessPartner

  // Business Partneer Person

  association [1..1] to I_BusinessPartner         as _BusinessPartnerPerson   on  $projection.BusinessPartnerPerson = _BusinessPartnerPerson.BusinessPartner

  // Contacts including Function and Department

  association [0..1] to I_BPContactToFuncAndDept  as _BPContactToFuncAndDept  on  $projection.BusinessPartnerCompany      = _BPContactToFuncAndDept.BusinessPartnerCompany
                                                                              and $projection.BusinessPartnerPerson       = _BPContactToFuncAndDept.BusinessPartnerPerson
                                                                              and _BPContactToFuncAndDept.ValidityEndDate >= $session.system_date

  // Contact Address

  association [0..1] to I_BpContactToAddress      as _BpContactToAddress      on  $projection.BusinessPartnerCompany  = _BpContactToAddress.BusinessPartnerCompany
                                                                              and $projection.BusinessPartnerPerson   = _BpContactToAddress.BusinessPartnerPerson
                                                                              and _BpContactToAddress.ValidityEndDate >= $session.system_date

  // Collection Segment

  association [0..1] to I_CollectionSegment       as _CollectionSegment       on  $projection.CollectionSegment = _CollectionSegment.CollectionSegment

  // Contact Person Function

  association [0..1] to I_ContactPersonFunction   as _ContactPersonFunction   on  $projection.ContactPersonFunction = _ContactPersonFunction.ContactPersonFunction

  // Contact Person Department

  association [0..1] to I_ContactPersondepartment as _ContactPersondepartment on  $projection.ContactPersonDepartment = _ContactPersondepartment.ContactPersonDepartment

  // Business Partner Relationship

  association [0..*] to I_BPRelationship          as _BPRelationship          on  $projection.RelationshipNumber     = _BPRelationship.RelationshipNumber
                                                                              and $projection.BusinessPartnerCompany = _BPRelationship.BusinessPartnerCompany
                                                                              and $projection.BusinessPartnerPerson  = _BPRelationship.BusinessPartnerPerson

  // Draft Administrative Data

  association [0..1] to I_DraftAdministrativeData as _DraftAdministrativeData on  $projection.DraftAdministrativeDataUUID  = _DraftAdministrativeData.DraftUUID
                                                                              and _DraftAdministrativeData.DraftEntityType = 'R_COLLECTIONCONTACTTP'

{
      //collcontdr

  key draftuuid                                           as DraftUUID,
      relationshipnumber                                  as RelationshipNumber,
      businesspartnercompany                              as BusinessPartnerCompany,
      businesspartnerperson                               as BusinessPartnerPerson,
      collectionsegment                                   as CollectionSegment,
      firstname                                           as FirstName,
      lastname                                            as LastName,
      phonenumber                                         as PhoneNumber,
      mobilenumber                                        as MobileNumber,
      faxnumber                                           as FaxNumber,
      emailaddress                                        as EmailAddress,
      contactpersonfunction                               as ContactPersonFunction,
      contactpersondepartment                             as ContactPersonDepartment,
      cast ( hasactiveentity as boolean preserving type ) as HasActiveEntity,
      draftentitycreationdatetime                         as DraftCreationDateTime,
      draftentitylastchangedatetime                       as DraftLastChangedDateTime,
      draftadministrativedatauuid                         as DraftAdministrativeDataUUID,

      // Exposed Associations

      _BPContactToFuncAndDept,
      _BpContactToAddress,
      _BusinessPartnerCompany,
      _BusinessPartnerPerson,
      _CollectionSegment,
      _ContactPersonFunction,
      _ContactPersondepartment,
      _BPRelationship,
      _DraftAdministrativeData

}