I_CnsldtnTaskRunStatusText_2

DDL: I_CNSLDTNTASKRUNSTATUSTEXT_2 Type: view_entity BASIC Package: FIN_CS_TASK_MON_STS

Consolidation Task Run Status - Text

I_CnsldtnTaskRunStatusText_2 is a Basic CDS View that provides data about "Consolidation Task Run Status - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, ConsolidationTaskRunStatus. It has 2 associations to related views. Part of development package FIN_CS_TASK_MON_STS.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t DomainText from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_CnsldtnTaskRunStatus_2 _CnsldtnTaskRunStatus $projection.ConsolidationTaskRunStatus = _CnsldtnTaskRunStatus.ConsolidationTaskRunStatus
[1..1] I_Language _Language $projection.Language = _Language.Language

Annotations (13)

NameValueLevelField
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey ConsolidationTaskRunStatus view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
Search.searchable true view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
EndUserText.label Consolidation Task Run Status - Text view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY ConsolidationTaskRunStatus
ConsolidationTaskRunStatusText
DomainValue dd07t domvalue_l
_CnsldtnTaskRunStatus _CnsldtnTaskRunStatus
_Language _Language 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@Analytics.dataExtraction.enabled: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
    usageType: {
        dataClass: #CUSTOMIZING,
        serviceQuality: #A,
        sizeCategory: #S
    },
    dataCategory: #TEXT,
    representativeKey: 'ConsolidationTaskRunStatus',
    modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
    supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #SQL_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #LANGUAGE_DEPENDENT_TEXT ]
}
@Search.searchable: true
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@EndUserText.label: 'Consolidation Task Run Status - Text'
/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ] } */
define view entity I_CnsldtnTaskRunStatusText_2 as 
  select from dd07t as DomainText
    
    association [1..1] to I_CnsldtnTaskRunStatus_2  as _CnsldtnTaskRunStatus   on $projection.ConsolidationTaskRunStatus = _CnsldtnTaskRunStatus.ConsolidationTaskRunStatus
    association [1..1] to I_Language                as _Language               on $projection.Language = _Language.Language

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( DomainText.ddlanguage as spras preserving type )                          as Language,
      
      @ObjectModel.foreignKey.association: '_CnsldtnTaskRunStatus'
  key cast( left( DomainText.domvalue_l,2 ) as fincs_taskrun_sts preserving type )    as ConsolidationTaskRunStatus,

      @Semantics.text
      @Search: {
        defaultSearchElement: true,
        ranking:#LOW,
        fuzzinessThreshold: 0.7
      }
      cast( DomainText.ddtext as fincs_taskrun_status_txt preserving type )           as ConsolidationTaskRunStatusText,
      
      @Consumption.hidden: true
      @Analytics.hidden: true
      DomainText.domvalue_l                                                           as DomainValue,
      
      _CnsldtnTaskRunStatus,
      _Language
}
where
      DomainText.domname  = 'FINCS_TASKRUN_STS'
  and DomainText.as4local = 'A';

Learn More