I_CnsldtnPostingLevelText_3

DDL: I_CNSLDTNPOSTINGLEVELTEXT_3 Type: view_entity BASIC Package: FIN_CS_MD_POSTINGLEVEL

Consolidation Posting Level - Text

I_CnsldtnPostingLevelText_3 is a Basic CDS View that provides data about "Consolidation Posting Level - Text" in SAP S/4HANA. It reads from 1 data source (P_CnsldtnDomainText) and exposes 6 fields with key fields Language, ConsolidationPostingLevel. It has 1 association to related views. Part of development package FIN_CS_MD_POSTINGLEVEL.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
P_CnsldtnDomainText P_CnsldtnDomainText from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_CnsldtnPostingLevel_2 _PostingLevel $projection.ConsolidationPostingLevel = _PostingLevel.ConsolidationPostingLevel

Annotations (14)

NameValueLevelField
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.representativeKey ConsolidationPostingLevel view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.sapObjectNodeType.name ConsolidationPostingLevelText view
Search.searchable true view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
EndUserText.label Consolidation Posting Level - Text view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY ConsolidationPostingLevel
ConsolidationPostingLevelText _Source DomainValueText
DomainValue _Source DomainValue
_Language _Source _Language
_PostingLevel _PostingLevel 
@Analytics: {
  dataExtraction.enabled: true
}
@AccessControl:{
  authorizationCheck: #NOT_REQUIRED
}
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S
  },
  representativeKey: 'ConsolidationPostingLevel',
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT ],
   sapObjectNodeType.name: 'ConsolidationPostingLevelText'
}
@Search.searchable: true
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@EndUserText.label: 'Consolidation Posting Level - Text'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_CnsldtnPostingLevelText_3
  as select from P_CnsldtnDomainText(P_DomainName : 'FC_PLEVL') as _Source

  association [1..1] to I_CnsldtnPostingLevel_2 as _PostingLevel on $projection.ConsolidationPostingLevel = _PostingLevel.ConsolidationPostingLevel

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key cast(_Source.Language as spras preserving type )                          as Language,

  key cast(left(_Source.DomainValue, 2) as fincs_postinglevel preserving type ) as ConsolidationPostingLevel,

      @Semantics.text
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      _Source.DomainValueText                                                   as ConsolidationPostingLevelText,

      @Consumption.hidden: true
      @Analytics.hidden: true
      _Source.DomainValue,


      _Source._Language,
      _PostingLevel
}
where
     _Source.DomainValue = ''
  or _Source.DomainValue = '00'
  or _Source.DomainValue = '01'
  or _Source.DomainValue = '0C'
  or _Source.DomainValue = '10'
  or _Source.DomainValue = '02'
  or _Source.DomainValue = '12'
  or _Source.DomainValue = '22'
  or _Source.DomainValue = '20'
  or _Source.DomainValue = '30';

Learn More