I_CmpstnCompChangeStatusText

@EndUserText.label: 'Text View for Component Change Status'

@AbapCatalog:
{
  sqlViewName: 'ICCCHANGESTST',
  compiler.compareFilter: true
}

// authorization check not required as view only reads domain values

@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  --Data category
  dataCategory: #TEXT,
  --Performance annotation
  usageType:
  {
    dataClass: #META,
    serviceQuality: #B,
    sizeCategory: #S
  },
  --Representative Key
  representativeKey: 'ChmlCompChangeStatus'
}
define view I_CmpstnCompChangeStatusText
  --Select data from domain value description table
  as select from dd07t as _CmpstnCompChangeStatus

  --association to I_Language
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      --Domain Value of CRR Status
  key substring(_CmpstnCompChangeStatus.domvalue_l, 1, 10) as ChmlCompChangeStatus,

      --Language
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(_CmpstnCompChangeStatus.ddlanguage as sylangu)  as Language,

      --language-dependent description of domain value
      @Semantics.text: true
      _CmpstnCompChangeStatus.ddtext                       as ChmlCompChangeStatusText,

      /* Associations */
      _Language
}
where
      _CmpstnCompChangeStatus.domname  = 'EHFND_CCI_CMPS_COMP_CHANGE_STS'
  and _CmpstnCompChangeStatus.as4local = 'A'