I_CmplRqVersStructure

@AbapCatalog.sqlViewName: 'ICQRSTRUCTURE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

//Compliance Requirement structure is customizing like data, Auth check not required

@AccessControl.authorizationCheck: #NOT_REQUIRED


@VDM.viewType: #BASIC
@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  },
  representativeKey: 'CmplRqVersParagraphUUID'
}

@EndUserText.label: 'Compliance Requirement Version Structure'
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_CmplRqVersStructure
  as select from ehfndd_req_struc
  association [1..1] to I_CmplRqVers as _CmplRqVers        on $projection.CmplRqVersUUID = _CmplRqVers.CmplRqVersUUID
  association [0..*] to I_CmplRqDomainTxt as _Text on $projection.CmplncRqmtVersPargphDomain = _Text.CmplRqDomain
  association [0..1] to I_User       as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User       as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID

{

  key db_key                                         									 as CmplRqVersParagraphUUID,
      bco_id                                         									 as CmplRqVersID,
      bco_key                                        									 as CmplncRqmtVersParagraphCntrlID,

      @ObjectModel.foreignKey.association: '_CmplRqVers'
      parent_key                                      									 as CmplRqVersUUID,

      // Admin data

      @Semantics.systemDateTime.createdAt: true
      cast(datetime_cr as timestamp preserving type) 									 as CreationUTCDateTime,
      @Semantics.user.createdBy: true 
      user_id_cr                                     									 as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(datetime_ch as timestamp preserving type) 									 as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      user_id_ch                                     									 as LastChangedByUser,

      paragraph_index                                									 as CmplRqVersParagraphIndexValue,
      paragraph_id                                   									 as CmplRqVersParagraphID,
      paragraph                                      									 as CmplRqVersParagraphName,
      paragraph_type                                 									 as CmplRqVersParagraphType,
      cast( paragraph_domain as ehfnd_req_domain_nce preserving type ) as CmplncRqmtVersPargphDomain,
      parent_ref_key                                 									 as CmplRqVersParagraphParentUUID,
      atf_key_ref                                    									 as CmplRqVersAttchFldrUUID,
      content_url                                    									 as CmplRqContentURL,
      content_link_name                              									 as CmplRqContentName,
      legal_text_url                                 									 as CmplRqLegalTextURL,
      legal_text_link_name                           									 as CmplRqLegalTextName,
      amendment_date                                 									 as CmplRqAmendmentDate,
      object_key                                     									 as CmplRqUUID,
      _CreatedByUser,
      _LastChangedByUser,

      _CmplRqVers,
      _Text
      
}