I_CmplRqRsltSubstListChkTP

----------------------------------------------------
-- Pattern: Substance List Check
-- Purpose: Substance List Check specific BO for a Compliance Requirement Results
----------------------------------------------------

@AbapCatalog:
{
  sqlViewName: 'ICRRSUBCHKTP',
  compiler.compareFilter: true,
  preserveKey: true
}

@EndUserText.label: 'CmplRqRslt Substance List Check'

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: 'EXTERNAL_CALCULATION', //TODO: This is inconsistent with I_CmplRqRsltTP

  writeDraftPersistence: 'ehpmaw_crr_slc',
  writeActivePersistence: 'ehfndv_crr',
  semanticKey:  [ 'CmplRqRsltUUID' ],
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  },
  entityChangeStateId: 'LastChangeDateTime',
  sapObjectNodeType.name: 'SubstanceListCheckAssessment'
}

define view I_CmplRqRsltSubstListChkTP
  as select from I_CmplRqRslt

  // Compliance Statements for CCI

  association [0..*] to I_CmplRqRsltSubLiChkStmntTP    as _CmplRqRsltCmplncStmnt     on $projection.CmplRqRsltUUID = _CmplRqRsltCmplncStmnt.CmplRqRsltUUID
  // Exemption valid for CCI, CSM and Substance

  association [0..*] to I_CmplRqRsltSubLiChkExmpTP     as _CmplRqRsltExemption       on $projection.CmplRqRsltUUID = _CmplRqRsltExemption.CmplRqRsltUUID
  // Substance Actions for Substances

  association [0..*] to I_CmplRqRsltSubstListChkActnTP as _CmplRqRsltSubstanceAction on $projection.CmplRqRsltUUID = _CmplRqRsltSubstanceAction.CmplRqRsltUUID
  // Additional Action Information for Substances

  association [0..1] to I_CmplRqRsltSubLiChkActnInfoTP as _CmplRqRsltActnInfo        on $projection.CmplRqRsltUUID = _CmplRqRsltActnInfo.CmplRqRsltUUID

  association [1..1] to I_CmplRqVersEnhanced           as _CmplRqVers                on  $projection.CmplRqVersUUID = _CmplRqVers.CmplRqVersUUID

{
      /****  Keys  ****/

      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      cast( CmplRqRsltUUID as  ehfnd_crr_active_uuid preserving type ) as ActiveCmplRqRsltUUID, --Active UUID of CRR

      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      ChmlCmplncInfoUUID,

      SubstanceUUID,

      ChmlSuplrMatlUUID,
      
      ChemicalCustomerMaterialUUID,

      /****  Content  ****/
      ComplianceRequirement,

      @ObjectModel.mandatory: true
      CreationDateTime,

      @ObjectModel.mandatory: true
      CreatedByUser,

      @ObjectModel.mandatory: true
      LastChangeDateTime,

      @ObjectModel.mandatory: true
      LastChangedByUser,

      CmplRqRsltProcessingStatus,

      Processor,

      ReleasedByUser,

      ValidityStartDateTime,

      ValidityEndDateTime,

      CmplRqRsltReldCmplncSts,

      CmplRqRsltCalculatedStatus,

      CmplRqRsltManualStatus,
      
      CmplRqRsltPrelimCmplncSts,

      CmplRqRsltStatusRemark,

      ChmlCompositionType,

      MaterialIsSold,

      MaterialIsTransported,

      MaterialIsSourced,

      MaterialIsProduced,

      /**** Associations ****/

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltCmplncStmnt,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltExemption,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltSubstanceAction,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltActnInfo,

      -- needed for Where Statement
      _CmplRqVers,

      ---- needed for authority check ----
      _ChmlCmplncInfo,
      _Substance

}
where
  -- Filter only Compliance Pattern Substance List Check related CRR
  _CmplRqVers.CmplRqPattern = 'CompliancePatternSubstListChk'