I_CmplRqRsltDaGdsMoOfTrDesc

@AbapCatalog.sqlViewName: 'ICRRDGMOTDSC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Modes of Transport Description'
@ObjectModel: { dataCategory: #TEXT,
                representativeKey: 'CmplRqRsltDngrsGdsModeOfTrUUID',
                usageType:{ serviceQuality: #A,        // < 15 msec

                            sizeCategory:  #L,         // < 10.000.000

                            dataClass: #TRANSACTIONAL } }
@VDM.viewType: #BASIC
define view I_CmplRqRsltDaGdsMoOfTrDesc
  as select from ehdgmd_crr_mot_t
  association [0..1] to I_Language              as _Language              on $projection.Language = _Language.Language
  association [1..1] to I_CmplRqRsltDaGdsMoOfTr as _CmplRqRsltDaGdsMoOfTr on $projection.CmplRqRsltDngrsGdsModeOfTrUUID = _CmplRqRsltDaGdsMoOfTr.CmplRqRsltDngrsGdsModeOfTrUUID
  association [1..1] to I_CmplRqRslt            as _CmplRqRslt            on $projection.CmplRqRsltUUID = _CmplRqRslt.CmplRqRsltUUID
{
      // Keys

  key cmplrqrsltdngrsgdsmodeoftruuid                                       as CmplRqRsltDngrsGdsModeOfTrUUID,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key language                                                             as Language,
      cmplrqrsltuuid                                                       as CmplRqRsltUUID,

      // Admin Fields

      @Semantics.systemDateTime.createdAt: true
      creationdatetime                                                     as CreationDateTime,
      @Semantics.user.createdBy: true
      cast( createdbyuser as vdm_createdbyuserid preserving type )         as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime                                                   as LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      cast( lastchangedbyuser as vdm_lastchangedbyuserid preserving type ) as LastChangedByUser,

      // Data

      @Semantics.text: true
      dangerousgooddescfordocuments                                        as DangerousGoodDescForDocuments,
      @Semantics.text: true
      dngrsgooddescforpackggdocstext                                       as DngrsGoodDescForPackggDocsText,
      @Semantics.text: true
      dngrsgoodhazardnotesdocstext                                         as DngrsGoodHazardNotesDocsText,
      @Semantics.text: true
      dngrsgoodmarkinglabeltext                                            as DngrsGoodMarkingLabelText,

      /* Associations */
      _Language,
      _CmplRqRsltDaGdsMoOfTr,
      _CmplRqRslt
}