I_ClfnClassType

@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'INGCCLSC2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Class Type of Classification'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.representativeKey: 'ClassType'
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #CUSTOMIZING
define view I_ClfnClassType
  as select from tcla as Basic
                          
      association [0..*] to I_ClfnClassTypeText as _ClassTypeText 
        on  _ClassTypeText.ClassType = $projection.ClassType
{
      @ObjectModel.text.association: '_ClassTypeText'
  key Basic.klart         as ClassType,
  key Basic.obtab         as ClfnObjectTable,
      Basic.multobj       as MultipleObjTableClfnIsAllowed,
      Basic.ausp_new      as ClfnNewNumberingIsAllowed,
//      Single.tracl      as,

      Basic.aediezuord    as EngChangeMgmtIsAllowed,   
//      Single.aeblgzuord as,

      Basic.mfkls         as MultipleClassIsAllowed,
      '00'                as ClfnObjectHierarchyLevel,
      Basic.varklart      as ClassTypeIsUsableInVarConfign,
      
      _ClassTypeText
} where
          Basic.multobj  <> 'X'
    and ( Basic.intklart <> 'X'            //internal class types are not included    

      or  Basic.klart    =  '026')         //required  


union

  select from tclao as Multiple
      inner join tcla as Basic
        on Basic.klart = Multiple.klart
        
      association [0..*] to I_ClfnClassTypeText as _ClassTypeText 
        on  _ClassTypeText.ClassType = $projection.ClassType
{   
      @ObjectModel.text.association: '_ClassTypeText'
  key Basic.klart         as ClassType,
      @ObjectModel.foreignKey.association: null
  key Multiple.obtab      as ClfnObjectTable,
      Basic.multobj       as MultipleObjTableClfnIsAllowed,
      Basic.ausp_new      as ClfnNewNumberingIsAllowed, 
//      Multiple.tracl      as,  

      Multiple.aediezuord as EngChangeMgmtIsAllowed,
//      tclao.aeblgzuord as,

      Multiple.mfkls      as MultipleClassIsAllowed,
      Multiple.zaehl      as ClfnObjectHierarchyLevel,
      Basic.varklart      as ClassTypeIsUsableInVarConfign,
      
      _ClassTypeText
} where
         Basic.multobj  =  'X'
   and ( Basic.intklart <> 'X'             //internal class types are not included      

     or  Basic.klart    =  '026' );        //required