I_ClfnCharcDescForKeyDate

DDL: I_CLFNCHARCDESCFORKEYDATE SQL: INGCCHR12_2 Type: view COMPOSITE Package: NGC_CORE_VDM

Description of Clfn Charc for Key Date

I_ClfnCharcDescForKeyDate is a Composite CDS View that provides data about "Description of Clfn Charc for Key Date" in SAP S/4HANA. It reads from 1 data source (I_ClfnCharcDesc) and exposes 8 fields with key fields CharcInternalID, Language. It has 1 association to related views. Part of development package NGC_CORE_VDM.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_ClfnCharcDesc CharcDesc from

Parameters (1)

NameTypeDefault
P_KeyDate sydate

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_ClfnCharacteristicForKeyDate _Characteristic $projection.CharcInternalID = _Characteristic.CharcInternalID

Annotations (15)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.sqlViewName INGCCHR12_2 view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Description of Clfn Charc for Key Date view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey CharcInternalID view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY CharcInternalID I_ClfnCharcDesc CharcInternalID
KEY Language I_ClfnCharcDesc Language
CharcDescription I_ClfnCharcDesc CharcDescription
ChangeNumber I_ClfnCharcDesc ChangeNumber
ValidityStartDate I_ClfnCharcDesc ValidityStartDate
ValidityEndDate I_ClfnCharcDesc ValidityEndDate
_Language _Language
_Characteristic _Characteristic 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'INGCCHR12_2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Description of Clfn Charc for Key Date'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'CharcInternalID'
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities:
  [  #LANGUAGE_DEPENDENT_TEXT,
     #CDS_MODELING_DATA_SOURCE,
     #CDS_MODELING_ASSOCIATION_TARGET,
     #SQL_DATA_SOURCE                  ]
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view I_ClfnCharcDescForKeyDate
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_ClfnCharcDesc as CharcDesc

      association [1..1] to I_ClfnCharacteristicForKeyDate as _Characteristic
        on $projection.CharcInternalID     = _Characteristic.CharcInternalID   
{
  key CharcDesc.CharcInternalID,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key CharcDesc.Language,
      @Semantics.text: true
      CharcDesc.CharcDescription,
      CharcDesc.ChangeNumber,
      @Semantics.businessDate.from: true
      CharcDesc.ValidityStartDate,
      @Semantics.businessDate.to: true
      CharcDesc.ValidityEndDate,

      _Language,
      _Characteristic
}
where CharcDesc.ValidityStartDate   <= $parameters.P_KeyDate
and   CharcDesc.ValidityEndDate     >= $parameters.P_KeyDate
and   CharcDesc.IsDeleted = ''

Learn More