I_ChmlSuplrMatlImprtRespyTP

@EndUserText.label: 'Supplier Material Import Responsibility - TP'

@AbapCatalog:
{
  sqlViewName: 'ICSMIRESP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations: ['_CreatedByUser','_LastChangedByUser']
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  --Transactional Annotations for the generated BO
  modelCategory: #BUSINESS_OBJECT,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: 'EXTERNAL_CALCULATION',
  writeDraftPersistence: 'EHFNDW_CSM_IRESP',
  writeActivePersistence: 'EHFNDD_CSM_IRESP',
  semanticKey:  [ 'ImprtRespyBuyingCompanyCode',
                  'ImprtRespyRcvgPlant' ],
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #XL,
    serviceQuality: #C
  }
}
define view I_ChmlSuplrMatlImprtRespyTP
  --Select data from basic view 'Import Responsibility'
  as select from I_ChmlSuplrMatlImprtRespy as ImportResponsibility

  --Nodes/Detaildata;
  -- Supplier Material
  association [1..1] to I_ChmlSuplrMatlTP     as _ChmlSuplrMatl   on $projection.ChmlSuplrMatlUUID = _ChmlSuplrMatl.ChmlSuplrMatlUUID
  association [1..1] to I_ProdCmplncPlantVH   as _PlantName       on  $projection.ImprtRespyRcvgPlant         = _PlantName.Plant
                                                                  and $projection.ImprtRespyBuyingCompanyCode = _PlantName.CompanyCode
{
      --UUID of Import Responsibility
  key ChmlSuplrMatlImprtRespyUUID,

      --Date/Time of creation
      @ObjectModel.readOnly: true
      CreationUTCDateTime,

      --Created by
      @ObjectModel.readOnly: true
      CreatedByUser,

      --Date/Time of change
      @ObjectModel.readOnly: true
      LastChangeUTCDateTime,

      --Changed by
      @ObjectModel.readOnly: true
      LastChangedByUser,

      --UUID of Supplier Material
      ChmlSuplrMatlUUID,

      --Buying Comapny Code
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ImprtRespyBuyingCompanyCode,

      --Receiving Plant
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ImprtRespyRcvgPlant,

      --Responsible Importer
      @ObjectModel.mandatory: true
      ImprtRespyRespImporter,

      -- Valid from date of setting
      @ObjectModel.mandatory: true
      ValidityStartDate,

      --Valid to date of setting
      @ObjectModel.mandatory: true
      ValidityEndDate,

      --Remark
      ImprtRespyRemarkText,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChmlSuplrMatl,
      _ResponsibleImporter,
      _ResponsibleImporterTxt,
      _ReceivingPlantDetails,
      _BuyingCompany,
      _CreatedByUser,
      _LastChangedByUser,
      _PlantName
}