I_ChmlCompositionType

--Label of view
@EndUserText.label: 'Chemical Composition Type'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICCOMPOSTYPE',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  // no authorization check required because view only reads customizing for which a check is not needed

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #BASIC

@ObjectModel:
{
  resultSet.sizeCategory: #XS,

  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  },
  representativeKey: 'ChmlCompositionType'
}

define view I_ChmlCompositionType
  --Select data from customizing table 'Composition Type'
  as select from ehfndc_cmpstype as CompositionType

  --Text association
  association [0..*] to I_ChmlCompositionTypeText as _Text on $projection.ChmlCompositionType = _Text.ChmlCompositionType
{
      --Composition Type
      @ObjectModel.text.association: '_Text'
  key CompositionType.composition_type     as ChmlCompositionType,

      /*Association*/
      _Text
}
-- Filter S_WORLD as it is only needed for Legal Areas
where
  $projection.chmlcompositiontype <> 'WORLDWIDE'