I_ChmlCompositionStatus

--Label of view
@EndUserText.label: 'Chemical Composition Release Status'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICCOMPOSSTATUS',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  // authorization check not required as view only reads domain values

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #BASIC

@ObjectModel:
{
  resultSet.sizeCategory: #XS,
  
  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  },
  representativeKey: 'ChmlCompositionStatus'
}

define view I_ChmlCompositionStatus
  --Select data from domain value table
  as select from dd07l as ChemicalCompositionStatus

  --Text association
  association [0..*] to I_ChmlCompositionStatusText    as _Text       on $projection.ChmlCompositionStatus = _Text.ChmlCompositionStatus
  association [0..*] to I_ChmlCompositionStatusLongTxt as _LongText   on $projection.ChmlCompositionStatus = _LongText.ChmlCompositionStatus
  association [0..*] to I_ChmlCompositionStsActnText   as _DetailText on $projection.ChmlCompositionStatus = _DetailText.ChmlCompositionStatus
{
      --Domain Value of Release Status
      @ObjectModel.text.association: '_Text'
  key substring(ChemicalCompositionStatus.domvalue_l, 1, 2) as ChmlCompositionStatus,

      /*Association*/
      _Text,
      _LongText,
      _DetailText
}
where
      ChemicalCompositionStatus.domname  = 'EHFND_CCI_CCMPS_STATUS'
  and ChemicalCompositionStatus.as4local = 'A'