I_ChmlCompTypeText

@EndUserText.label: 'Language-Depenedent Description of Type of Chem. Component'

@AbapCatalog:
{
  sqlViewName: 'ICCOMPTYPET',
  compiler.compareFilter: true
}

// no authorization check required because view only reads customizing for which a check is not needed

@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  --Performance Annotations
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #B
  },
  --Data category
  dataCategory: #TEXT,
  --Representative Key
  representativeKey: 'ChmlCompType'
}

--Search
@Search.searchable: true

define view I_ChmlCompTypeText
  --Select data from customizing table 'Language-dependent Description for Component Type'
  as select from ehfndc_comptypet as ChemComponentTypeText

  --Link to CDS view I_Language
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      --Type of Chemical Component
  key cast(ChemComponentTypeText.type as ehfnd_cci_ccomp_type_nce preserving type ) as ChmlCompType,

      --Language
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key ChemComponentTypeText.langu                                                   as Language,

      --Description of Type
      @Semantics.text: true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      ChemComponentTypeText.type_description                                        as ChmlCompTypeName,

      /* Associations */
      _Language
}