I_ChgRecdVarBillOfMatTP_2

@AbapCatalog.sqlViewName: 'ICRREFVARBMTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'TP  ChgRecd variant BOM'
@VDM.viewType: #TRANSACTIONAL

//@ObjectModel: {

//semanticKey: [ 'Material','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant']

//               writeDraftPersistence: 'PLMCRREFVARBOM_D',

//                createEnabled,

//                deleteEnabled,

//                updateEnabled

//              }


@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #XXL}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

define view I_ChgRecdVarBillOfMatTP_2
  as select from           I_ChgRecdRefVarBOMBsc as reference_bom
    left outer to one join I_MaterialBOMLink     as BOMLink on  reference_bom.ChgRecRefInternalKey1 = BOMLink.BillOfMaterialCategory
                                                            and reference_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                            and reference_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant
                                                            and reference_bom.ChgRecRefInternalKey4 = BOMLink.Material
  association        to parent I_ChangeRecordTP_2 as _ChangeRecordAPITP on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP as _ChangeRecordTP on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  //association [0..1] to E_ChgRecdRefEquipBOMBsc as _EQBOMExtension on $projection.ChangeRecordReferenceUUID = _EQBOMExtension.ChangeRecordReferenceUUID


{

  key        reference_bom.ChangeRecordReferenceUUID,
             

             case
               when BOMLink.Material is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 1, 40) as matnr)
               else cast(BOMLink.Material as matnr)
               end                                                      as Material,

             case
              when BOMLink.Plant is null then  cast(SUBSTRING( reference_bom.ChangeRecordReference, 41, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,

             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (SUBSTRING( reference_bom.ChangeRecordReference, 45, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,

             case
              when BOMLink.BillOfMaterialVariant is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 46, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,

             reference_bom.ChangeRecord,
             reference_bom.ChangeRecordUUID,
             reference_bom.ChangeRecordReferenceType,
             reference_bom.ChangeRecordReferenceSubtype,
             reference_bom.ChangeRecordReference,
             reference_bom.ParentChangeRecordRefUUID,
             reference_bom.IsMainReference,
             BOMLink.BillOfMaterialCategory,          
             reference_bom.ChangeNumber,
             reference_bom.CreatedByUser,
             reference_bom.CreationDateTime,
             reference_bom.LastChangedByUser,
             reference_bom.LastChangeDateTime,
             reference_bom.ChangeRecordItemRelevance,
             reference_bom.ChangeRecordVirtualRefInd,
             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             reference_bom.ChangeRecordRefObjectUUID,
             reference_bom.ChangeRecordItemProcgStatus,
             reference_bom.ChgRecdCurrentItemProcgStatus,
             _ChangeRecordTP,
             _ChangeRecordAPITP

}
where
      reference_bom.ChangeRecordReferenceType    = 'VBM'
  and ( reference_bom.ChangeRecordReference != ''  or  BOMLink.IsConfiguredMaterial = 'X' )