I_ChgRecdRefMaintTskListTP_2

@AbapCatalog.sqlViewName: 'ICRREFMTLTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
                         
@EndUserText.label: 'Chg Red Ref Obj Maint Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

define view I_ChgRecdRefMaintTskListTP_2
  as select from           I_ChgRecdRefMaintTskListBsc as reference_mtl
    left outer to one join I_BillOfOperations          as MaintenanceTaskList on  reference_mtl.ChgRecRefInternalKey1 = MaintenanceTaskList.BillOfOperationsType
                                                                              and reference_mtl.ChgRecRefInternalKey2 = MaintenanceTaskList.BillOfOperationsGroup
                                                                              and reference_mtl.ChgRecRefInternalKey3 = MaintenanceTaskList.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2  as _ChangeRecordAPITP       on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP               on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefMaintTskListBsc as _MaintenanceTaskListExtension on $projection.ChangeRecordReferenceUUID = _MaintenanceTaskListExtension.ChangeRecordReferenceUUID
{
  key   reference_mtl.ChangeRecordReferenceUUID,
        case
           when MaintenanceTaskList.BillOfOperationsType is null then cast(SUBSTRING( reference_mtl.ChangeRecordReference, 1, 1) as plnty)
           else cast(MaintenanceTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

     
        case
        when MaintenanceTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_mtl.ChangeRecordReference, 2, 9) as plnnr)
        else cast(MaintenanceTaskList.BillOfOperationsGroup as plnnr)
        end                             as RefMaintTskListGroup,

     
        case
         when MaintenanceTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( reference_mtl.ChangeRecordReference, 10, 2) as plnal)
         else cast(MaintenanceTaskList.BillOfOperationsVariant as plnal)
         end                            as RefMaintTskList,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
//        // deprecated,  should not be used

//        cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_mtl.ChangeRecordUUID,
        reference_mtl.ChangeRecord,
        reference_mtl.ChangeRecordReferenceType,
        reference_mtl.ChangeRecordReferenceSubtype,
        reference_mtl.ChangeRecordRefObjectUUID,
        reference_mtl.ChangeRecordReference,
        reference_mtl.ParentChangeRecordRefUUID,
        reference_mtl.IsMainReference,
        reference_mtl.CreatedByUser,
        reference_mtl.CreationDateTime,
        reference_mtl.LastChangedByUser,
        reference_mtl.LastChangeDateTime,
        reference_mtl.ChangeRecordItemRelevance,
        reference_mtl.ChangeRecordVirtualRefInd,
        reference_mtl.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
     MaintenanceTaskList.BillOfOperationsType = 'A'
  or MaintenanceTaskList.BillOfOperationsType is null