I_ChgRecdRefMaintTskListTP

@AbapCatalog.sqlViewName: 'ICRREFMTLTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Ref Obj Maint Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFMTL_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdRefMaintTskListTP
  as select from           I_ChgRecdRefMaintTskListBsc as MaintenanceTaskListReference
    left outer to one join I_BillOfOperations          as MaintenanceTaskList on  MaintenanceTaskListReference.ChgRecRefInternalKey1 = MaintenanceTaskList.BillOfOperationsType
                                                                              and MaintenanceTaskListReference.ChgRecRefInternalKey2 = MaintenanceTaskList.BillOfOperationsGroup
                                                                              and MaintenanceTaskListReference.ChgRecRefInternalKey3 = MaintenanceTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP               on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefMaintTskListBsc as _MaintenanceTaskListExtension on $projection.ChangeRecordReferenceUUID = _MaintenanceTaskListExtension.ChangeRecordReferenceUUID
{
  key   MaintenanceTaskListReference.ChangeRecordReferenceUUID,
        case
           when MaintenanceTaskList.BillOfOperationsType is null then cast(SUBSTRING( MaintenanceTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(MaintenanceTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when MaintenanceTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( MaintenanceTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(MaintenanceTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when MaintenanceTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( MaintenanceTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(MaintenanceTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        MaintenanceTaskListReference.ChangeRecordUUID,
        MaintenanceTaskListReference.ChangeRecordReferenceType,
        MaintenanceTaskListReference.ChangeRecordReferenceSubtype,
        MaintenanceTaskListReference.ChangeRecordRefObjectUUID,
        MaintenanceTaskListReference.ChangeRecordReference,
        MaintenanceTaskListReference.ParentChangeRecordRefUUID,
        MaintenanceTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,

        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        MaintenanceTaskListReference.CreatedByUser,
        MaintenanceTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        MaintenanceTaskListReference.LastChangedByUser,
        MaintenanceTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        MaintenanceTaskListReference.ChangeRecordItemRelevance,
        MaintenanceTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        MaintenanceTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        MaintenanceTaskListReference.ChgRecdCurrentItemProcgStatus,
        MaintenanceTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        MaintenanceTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        MaintenanceTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     MaintenanceTaskList.BillOfOperationsType = 'A'
  or MaintenanceTaskList.BillOfOperationsType is null