I_ChgRecdRefMBOMDataMigrtn

@AbapCatalog.sqlViewName: 'ICHGRECREFMBMDM'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #X,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Change Record Reference MBOM Data Mgrtn'

/*
  The three branches of the union take care of the following
   1) Records with existing reference which has not been migrated yet.
   2) Records with existing references which has been migrated (status = 01).
   3) Data which represents planned records. The planned records are stored as a string and the helper CDS view
      is responsible for splitting those into data fields.
 */
define view I_ChgRecdRefMBOMDataMigrtn
  as select from P_ChgRecdRefMBMBfrDataMigrtn as beforeDataMigrtn
    inner join   R_ChgRecdDataMigrationStatus as tf on(
      tf.ChgRecdDataMigrationPhase                                                 = 'X'
    )
                                                    or(
                                                      tf.ChgRecdDataMigrationPhase = 'R'
                                                    )
{
  key beforeDataMigrtn.ChangeRecordReferenceUUID,
      beforeDataMigrtn.Material,
      beforeDataMigrtn.Plant,
      beforeDataMigrtn.BillOfMaterialVariantUsage,
      beforeDataMigrtn.BillOfMaterialVariant,
      beforeDataMigrtn.BillOfMaterial,
      beforeDataMigrtn.BillOfMaterialCategory,
      beforeDataMigrtn.BillOfMaterialVersion,
      beforeDataMigrtn.ChangeRecord,
      beforeDataMigrtn.ChangeRecordUUID,
      beforeDataMigrtn.ChangeRecordReferenceType,
      beforeDataMigrtn.ChangeRecordReferenceSubtype,
      beforeDataMigrtn.ChangeRecordRefObjectUUID,
      beforeDataMigrtn.ParentChangeRecordRefUUID,
      beforeDataMigrtn.IsMainReference,
      beforeDataMigrtn.ChangeRecordReference,
      beforeDataMigrtn.ChgRecRefInternalKey1,
      beforeDataMigrtn.ChgRecRefInternalKey2,
      beforeDataMigrtn.ChgRecRefInternalKey3,
      beforeDataMigrtn.ChgRecRefInternalKey4,
      beforeDataMigrtn.CreatedByUser,
      beforeDataMigrtn.CreationDateTime,
      beforeDataMigrtn.LastChangedByUser,
      beforeDataMigrtn.LastChangeDateTime,
      beforeDataMigrtn.ChangeRecordVirtualRefInd,
      beforeDataMigrtn.ChangeRecordItemRelevance,
      beforeDataMigrtn.ChgRecdDataMigrationStatus,
      beforeDataMigrtn.ChangeRecordItemProcgStatus,
      beforeDataMigrtn.ChgRecdItmTgtSts,
      beforeDataMigrtn.ChgRecdItmDSgntr,
      beforeDataMigrtn.ChgRecdReasonForChange,
      beforeDataMigrtn.ExpdCompltnDte,
      beforeDataMigrtn.ChgRecdAuthznGrpText,
      beforeDataMigrtn.ChgRecdNmbrChgSts,
      beforeDataMigrtn.ChangeNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      beforeDataMigrtn._ChangeRecordBsc
}
where
  (
    (
         tf.ChgRecdDataMigrationPhase                = 'X'
    )
    or(
         beforeDataMigrtn.ChgRecdDataMigrationStatus is initial
      or beforeDataMigrtn.ChgRecdDataMigrationStatus is null
    )
  )
  and    ChangeRecordVirtualRefInd                   = ''
union all select from P_ChgRecdRefMBMAfterDataMigrtn as afterDataMigrtn
  inner join          R_ChgRecdDataMigrationStatus   as tf on(
    tf.ChgRecdDataMigrationPhase                                                          = 'F'
  )
                                                           or(
                                                             tf.ChgRecdDataMigrationPhase = 'R'
                                                           )
{
  key afterDataMigrtn.ChangeRecordReferenceUUID,
      afterDataMigrtn.Material,
      afterDataMigrtn.Plant,
      afterDataMigrtn.BillOfMaterialVariantUsage,
      afterDataMigrtn.BillOfMaterialVariant,
      afterDataMigrtn.BillOfMaterial,
      afterDataMigrtn.BillOfMaterialCategory,
      afterDataMigrtn.BillOfMaterialVersion,
      afterDataMigrtn.ChangeRecord,
      afterDataMigrtn.ChangeRecordUUID,
      afterDataMigrtn.ChangeRecordReferenceType,
      afterDataMigrtn.ChangeRecordReferenceSubtype,
      afterDataMigrtn.ChangeRecordRefObjectUUID,
      afterDataMigrtn.ParentChangeRecordRefUUID,
      afterDataMigrtn.IsMainReference,
      afterDataMigrtn.ChangeRecordReference,
      afterDataMigrtn.ChgRecRefInternalKey1,
      afterDataMigrtn.ChgRecRefInternalKey2,
      afterDataMigrtn.ChgRecRefInternalKey3,
      afterDataMigrtn.ChgRecRefInternalKey4,
      afterDataMigrtn.CreatedByUser,
      afterDataMigrtn.CreationDateTime,
      afterDataMigrtn.LastChangedByUser,
      afterDataMigrtn.LastChangeDateTime,
      afterDataMigrtn.ChangeRecordVirtualRefInd,
      afterDataMigrtn.ChangeRecordItemRelevance,
      afterDataMigrtn.ChgRecdDataMigrationStatus,
      afterDataMigrtn.ChangeRecordItemProcgStatus,
      afterDataMigrtn.ChgRecdItmTgtSts,
      afterDataMigrtn.ChgRecdItmDSgntr,
      afterDataMigrtn.ChgRecdReasonForChange,
      afterDataMigrtn.ExpdCompltnDte,
      afterDataMigrtn.ChgRecdAuthznGrpText,
      afterDataMigrtn.ChgRecdNmbrChgSts,
      afterDataMigrtn.ChangeNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      afterDataMigrtn._ChangeRecordBsc
}
where
  (
    (
      tf.ChgRecdDataMigrationPhase               = 'F'
    )
    or(
      afterDataMigrtn.ChgRecdDataMigrationStatus = '01'
    )
  )
  and ChangeRecordVirtualRefInd                  = ''
union all select from P_ChgRecdRefMfgBOMVirtual
{
  key ChangeRecordReferenceUUID,
      Material,
      Plant,
      BillOfMaterialVariantUsage,
      BillOfMaterialVariant,
      BillOfMaterial,
      BillOfMaterialCategory,
      BillOfMaterialVersion,
      ChangeRecord,
      ChangeRecordUUID,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ChangeRecordRefObjectUUID,
      ParentChangeRecordRefUUID,
      IsMainReference,
      ChangeRecordReference,
      ChgRecRefInternalKey1,
      ChgRecRefInternalKey2,
      ChgRecRefInternalKey3,
      ChgRecRefInternalKey4,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,
      ChangeRecordVirtualRefInd,
      ChangeRecordItemRelevance,
      ChgRecdDataMigrationStatus,
      ChangeRecordItemProcgStatus,
      ChgRecdItmTgtSts,
      ChgRecdItmDSgntr,
      ChgRecdReasonForChange,
      ExpdCompltnDte,
      ChgRecdAuthznGrpText,
      ChgRecdNmbrChgSts,
      ChangeNumber,


      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecordBsc
}
where
  ChangeRecordVirtualRefInd = 'X'