I_ChgRecdRefLabelTP

@AbapCatalog.sqlViewName: 'ICHGRECREFLBLTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@EndUserText.label: 'Change Record Object Reference Label'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
semanticKey: ['LabelSetSpecificationIntID'],
                writeDraftPersistence: 'PLMCRREFLBL_D',
                createEnabled : 'EXTERNAL_CALCULATION',
                deleteEnabled : 'EXTERNAL_CALCULATION',
                updateEnabled : 'EXTERNAL_CALCULATION'
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view I_ChgRecdRefLabelTP
  as select from           I_ChgRecdRefLabelBsc as reference_lbl
    left outer to one join I_LabelSet           as _LabelSet on reference_lbl.ChgRecRefInternalKey1 = _LabelSet.LabelSetInternalID

  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecord             on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID

  association [1..1] to I_SpecificationNonHistoric  as _SpecificationNonHistoric on $projection.LabelSetSpecificationIntID = _SpecificationNonHistoric.SpecificationInternalID

  association [0..1] to I_LabelSetIdfrBscForKeyDate as _Identifier               on $projection.LabelSetSpecificationIntID = _Identifier.SpecificationInternalID

  association [0..1] to E_ChgRecdRefLabelBsc        as _LabelExtension           on $projection.ChangeRecordReferenceUUID = _LabelExtension.ChangeRecordReferenceUUID
{
  key reference_lbl.ChangeRecordReferenceUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
          when _SpecificationNonHistoric.Specification is null then cast(SUBSTRING( reference_lbl.ChangeRecordReference, 1, 12) as esesubid)
          else cast(_SpecificationNonHistoric.Specification as esesubid)
            end                            as Specification,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
      when _LabelSet.LabelSetAlternativeNumber is null then  cast(SUBSTRING( reference_lbl.ChangeRecordReference, 13, 3) as rmsle_alt_no)
      else cast(_LabelSet.LabelSetAlternativeNumber as rmsle_alt_no)
             end                           as LabelSetAlternativeNumber,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
      when _LabelSet.LabelSetVersionNumber is null then cast (SUBSTRING( reference_lbl.ChangeRecordReference, 16, 3) as rmsle_vers_no)
      else cast(_LabelSet.LabelSetVersionNumber as rmsle_vers_no)
             end                           as LabelSetVersionNumber,
      _LabelSet.LabelSetInternalID         as LabelSetInternalID,
      _LabelSet.LabelSetSpecificationIntID as LabelSetSpecificationIntID,
      //_Identifier(P_KeyDate : $session.system_date).SpecIdfgDescText,

      cast('' as eseident)                 as SpecIdfgDescText,
      reference_lbl.ChangeRecordUUID,
      reference_lbl.ChangeRecord,
      reference_lbl.ChangeRecordType,
      reference_lbl.ChangeRecordReferenceType,
      reference_lbl.ChangeRecordReferenceSubtype,
      reference_lbl.ChangeRecordReference,
      reference_lbl.ParentChangeRecordRefUUID,
      reference_lbl.IsMainReference,
      ChgRecdReasonForChange,
      ExpdCompltnDte,
      ChgRecdAuthznGrpText,
      ChgRecdNmbrChgSts,
       
      
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      reference_lbl.CreatedByUser,
      reference_lbl.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      reference_lbl.LastChangedByUser,
      reference_lbl.LastChangeDateTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      reference_lbl.ChangeRecordItemRelevance,
      reference_lbl.ChangeRecordVirtualRefInd,
      reference_lbl.ChgRecRefInternalKey1,
      reference_lbl.ChgRecRefInternalKey2,
      reference_lbl.ChgRecRefInternalKey3,
      reference_lbl.ChgRecRefInternalKey4,
      reference_lbl.ChangeRecordRefObjectUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      reference_lbl.ChangeRecordItemProcgStatus,
      @ObjectModel.readOnly: true
      reference_lbl.ChgRecdCurrentItemProcgStatus,
      @ObjectModel.readOnly: true
      reference_lbl.ChgRecdItmTgtSts,
      @ObjectModel.readOnly: true
      reference_lbl.ChgRecdItmDSgntr,
      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecord,
      _SpecificationNonHistoric
}