I_ChgRecdRateRtgTskListTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFRROTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Chg Record Rate Routing Task List'
define view I_ChgRecdRateRtgTskListTP_2
  as select from           I_ChgRecdRateRtgTskListBsc as reference_rro
    left outer to one join I_BillOfOperations         as RateRtgTskList on  reference_rro.ChgRecRefInternalKey1 = RateRtgTskList.BillOfOperationsType
                                                                        and reference_rro.ChgRecRefInternalKey2 = RateRtgTskList.BillOfOperationsGroup
                                                                        and reference_rro.ChgRecRefInternalKey3 = RateRtgTskList.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2  as _ChangeRecordAPITP       on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP          on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRateRtgTskListBsc as _RateRtgTskListExtension on $projection.ChangeRecordReferenceUUID = _RateRtgTskListExtension.ChangeRecordReferenceUUID
{
  key   reference_rro.ChangeRecordReferenceUUID,
        case
           when RateRtgTskList.BillOfOperationsType is null then cast(SUBSTRING( reference_rro.ChangeRecordReference, 1, 1) as plnty)
           else cast(RateRtgTskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when RateRtgTskList.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_rro.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RateRtgTskList.BillOfOperationsGroup as plnnr)
        end                             as RateRtgTskListGroup,

        case
         when RateRtgTskList.BillOfOperationsVariant is null then cast (SUBSTRING( reference_rro.ChangeRecordReference, 10, 2) as plnal)
         else cast(RateRtgTskList.BillOfOperationsVariant as plnal)
         end                            as RateRtgTskList,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        //cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_rro.ChangeRecordUUID,
        reference_rro.ChangeRecord,
        reference_rro.ChangeRecordReferenceType,
        reference_rro.ChangeRecordReferenceSubtype,
        reference_rro.ChangeRecordRefObjectUUID,
        reference_rro.ChangeRecordReference,
        reference_rro.ParentChangeRecordRefUUID,
        reference_rro.IsMainReference,
        reference_rro.CreatedByUser,
        reference_rro.CreationDateTime,
        reference_rro.LastChangedByUser,
        reference_rro.LastChangeDateTime,
        reference_rro.ChangeRecordItemRelevance,
        reference_rro.ChangeRecordVirtualRefInd,
        reference_rro.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
//  RateRtgTskList.BillOfOperationsType = 'R'

reference_rro.ChangeRecordReferenceType = 'RRO'