I_ChgRecdRateRtgTskListTP

@AbapCatalog.sqlViewName: 'ICRREFRROTLTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Ref Obj Rate Rtg Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFRROTL_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdRateRtgTskListTP
  as select from           I_ChgRecdRateRtgTskListBsc as RateRtgTaskListReference
    left outer to one join I_BillOfOperations         as RateRtgTaskList on  RateRtgTaskListReference.ChgRecRefInternalKey1 = RateRtgTaskList.BillOfOperationsType
                                                                         and RateRtgTaskListReference.ChgRecRefInternalKey2 = RateRtgTaskList.BillOfOperationsGroup
                                                                         and RateRtgTaskListReference.ChgRecRefInternalKey3 = RateRtgTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP           on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRateRtgTskListBsc as _RateRtgTaskListExtension on $projection.ChangeRecordReferenceUUID = _RateRtgTaskListExtension.ChangeRecordReferenceUUID
{
  key   RateRtgTaskListReference.ChangeRecordReferenceUUID,
        case
           when RateRtgTaskList.BillOfOperationsType is null then cast(SUBSTRING( RateRtgTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(RateRtgTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when RateRtgTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( RateRtgTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RateRtgTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when RateRtgTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( RateRtgTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(RateRtgTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        RateRtgTaskListReference.ChangeRecordUUID,
        RateRtgTaskListReference.ChangeRecordReferenceType,
        RateRtgTaskListReference.ChangeRecordReferenceSubtype,
        RateRtgTaskListReference.ChangeRecordRefObjectUUID,
        RateRtgTaskListReference.ChangeRecordReference,
        RateRtgTaskListReference.ParentChangeRecordRefUUID,
        RateRtgTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,
        
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        RateRtgTaskListReference.CreatedByUser,
        RateRtgTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        RateRtgTaskListReference.LastChangedByUser,
        RateRtgTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RateRtgTaskListReference.ChangeRecordItemRelevance,
        RateRtgTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RateRtgTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        RateRtgTaskListReference.ChgRecdCurrentItemProcgStatus,
        RateRtgTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        RateRtgTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        RateRtgTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     RateRtgTaskList.BillOfOperationsType = 'R'
  or RateRtgTaskList.BillOfOperationsType is null