I_ChgRecdFuncLocTskListTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFFTLTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Chg Record Functional Location Task List'
define view I_ChgRecdFuncLocTskListTP_2
  as select from           I_ChgRecdFuncLocTskListBsc as reference_ftl
    left outer to one join I_BillOfOperations         as FuncLocTskList on  reference_ftl.ChgRecRefInternalKey1 = FuncLocTskList.BillOfOperationsType
                                                                        and reference_ftl.ChgRecRefInternalKey2 = FuncLocTskList.BillOfOperationsGroup
                                                                        and reference_ftl.ChgRecRefInternalKey3 = FuncLocTskList.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2  as _ChangeRecordAPITP       on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP          on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdFuncLocTskListBsc as _FuncLocTskListExtension on $projection.ChangeRecordReferenceUUID = _FuncLocTskListExtension.ChangeRecordReferenceUUID
{
  key   reference_ftl.ChangeRecordReferenceUUID,
        case
           when FuncLocTskList.BillOfOperationsType is null then cast(SUBSTRING( reference_ftl.ChangeRecordReference, 1, 1) as plnty)
           else cast(FuncLocTskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when FuncLocTskList.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_ftl.ChangeRecordReference, 2, 9) as plnnr)
        else cast(FuncLocTskList.BillOfOperationsGroup as plnnr)
        end                             as FuncLocTskListGroup,

        case
         when FuncLocTskList.BillOfOperationsVariant is null then cast (SUBSTRING( reference_ftl.ChangeRecordReference, 10, 2) as plnal)
         else cast(FuncLocTskList.BillOfOperationsVariant as plnal)
         end                            as FuncLocTskList,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        //cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_ftl.ChangeRecordUUID,
        reference_ftl.ChangeRecord,
        reference_ftl.ChangeRecordReferenceType,
        reference_ftl.ChangeRecordReferenceSubtype,
        reference_ftl.ChangeRecordRefObjectUUID,
        reference_ftl.ChangeRecordReference,
        reference_ftl.ParentChangeRecordRefUUID,
        reference_ftl.IsMainReference,
        reference_ftl.CreatedByUser,
        reference_ftl.CreationDateTime,
        reference_ftl.LastChangedByUser,
        reference_ftl.LastChangeDateTime,
        reference_ftl.ChangeRecordItemRelevance,
        reference_ftl.ChangeRecordVirtualRefInd,
        reference_ftl.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
//  FuncLocTskList.BillOfOperationsType = 'T'

reference_ftl.ChangeRecordReferenceType = 'FTL'