I_ChangeRecdRefLabelSetTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFLBLTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Change Record Reference Object Label Set'
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XXL}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view I_ChangeRecdRefLabelSetTP_2
  as select from           I_ChgRecdRefLabelBsc as reference_lbl
    left outer to one join I_LabelSet           as _LabelSet on reference_lbl.ChgRecRefInternalKey1 = _LabelSet.LabelSetInternalID

  association        to parent I_ChangeRecordTP_2   as _ChangeRecordAPITP        on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID

  association [1..1] to I_SpecificationNonHistoric  as _SpecificationNonHistoric on $projection.LabelSetSpecificationIntID = _SpecificationNonHistoric.SpecificationInternalID

  association [0..1] to I_LabelSetIdfrBscForKeyDate as _Identifier               on $projection.LabelSetSpecificationIntID = _Identifier.SpecificationInternalID

  association [0..1] to E_ChgRecdRefLabelBsc        as _LabelExtension           on $projection.ChangeRecordReferenceUUID = _LabelExtension.ChangeRecordReferenceUUID
{
  key reference_lbl.ChangeRecordReferenceUUID,
      case
          when _SpecificationNonHistoric.Specification is null then cast(SUBSTRING( reference_lbl.ChangeRecordReference, 1, 12) as esesubid)
          else cast(_SpecificationNonHistoric.Specification as esesubid)
            end                            as LabelSetSpecification,

      case
      when _LabelSet.LabelSetAlternativeNumber is null then  cast(SUBSTRING( reference_lbl.ChangeRecordReference, 13, 3) as rmsle_alt_no)
      else cast(_LabelSet.LabelSetAlternativeNumber as rmsle_alt_no)
             end                           as LabelSetAlternativeNumber,

      case
      when _LabelSet.LabelSetVersionNumber is null then cast (SUBSTRING( reference_lbl.ChangeRecordReference, 16, 3) as rmsle_vers_no)
      else cast(_LabelSet.LabelSetVersionNumber as rmsle_vers_no)
             end                           as LabelSetVersionNumber,
      _LabelSet.LabelSetInternalID         as LabelSetInternalID,
      _LabelSet.LabelSetSpecificationIntID as LabelSetSpecificationIntID,
      _Identifier(P_KeyDate : $session.system_date).SpecIdfgDescText,
      reference_lbl.ChangeRecordUUID,
      reference_lbl.ChangeRecord,
      reference_lbl.ChangeRecordType,
      reference_lbl.ChangeRecordReferenceType,
      reference_lbl.ChangeRecordReferenceSubtype,
      reference_lbl.ChangeRecordReference,
      reference_lbl.ParentChangeRecordRefUUID,
      reference_lbl.IsMainReference,
      reference_lbl.CreatedByUser,
      reference_lbl.CreationDateTime,
      reference_lbl.LastChangedByUser,
      reference_lbl.LastChangeDateTime,
      reference_lbl.ChangeRecordItemRelevance,
      reference_lbl.ChangeRecordItemProcgStatus,
      reference_lbl.ChangeRecordVirtualRefInd,
      reference_lbl.ChgRecRefInternalKey1,
      reference_lbl.ChgRecRefInternalKey2,
      reference_lbl.ChgRecRefInternalKey3,
      reference_lbl.ChgRecRefInternalKey4,
      reference_lbl.ChangeRecordRefObjectUUID,
      _ChangeRecordAPITP,
      _SpecificationNonHistoric
}