I_ChangeMasterObjTypeAssgmtTP

@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@EndUserText.label: 'Change Number Object Type Assignment (Transactional Proc.)'
define view entity I_ChangeMasterObjTypeAssgmtTP
  as select from P_ChangeMasterObjTypeAssgmtTP
  association to parent I_ChangeMasterTP as _ChangeMaster on $projection.ChangeNumber = _ChangeMaster.ChangeNumber
{
  key ChangeNumber,

  key ChangeNumberObjectType as ChangeNumberObjectType,

  key cast(
       case ChangeNumberObjectType
         when '02' then 'MaterialBOM'
         when '07' then 'SalesOrderBOM'
         when '12' then 'ProductionRouting'
         when '31' then 'DocumentInfoRecord'
         when '41' then 'Material'
         when '51' then 'ClassificationCharacteristic'
         when '52' then 'ClassificationClassCharcAssgmt'
         when '53' then 'ClassificationValuation'
         when '54' then 'VariantConfigurationObjDpndcy'
         when '55' then 'VariantConfigurationProfile'
         when '63' then 'VariantConfigurationVariantTbl'
         when '83' then 'Recipe'
         when '08' then 'WBSBillOfMaterial'
      end as sbo_bo_type )   as SAPObjectType,

      IsActiveForChangeNumber,
      IsLockedForChanges,
      IsPartiallyDisplayed,

      ObjMgmtRecdIsRequired,
      ObjMgmtRecdIsGenerated,
      ObjMgmtRecdIsAutomlyCrted,
      ObjMgmtRecdIsAutomlyCrtedByDlg,

      ObjectTypeCreationDate,
      ObjectTypeCreatedByUser,
      ObjectTypeLastChangedDate,
      ObjectTypeLastChangedByUser,

      // for ETag handling

      _ChangeMaster.ChangeNumberLastChgdDateTime,

      _ChangeMaster
}
where
     ChangeNumberObjectType = '02' // 'MaterialBOM'

  or ChangeNumberObjectType = '07' // 'SalesOrderBOM'

  or ChangeNumberObjectType = '12' // 'ProductionRouting'   

  or ChangeNumberObjectType = '31' // 'DocumentInfoRecord'

  or ChangeNumberObjectType = '41' // 'Material'

  or ChangeNumberObjectType = '51' // 'ClassificationCharacteristic'

  or ChangeNumberObjectType = '52' // 'ClassificationClassCharcAssgmt'

  or ChangeNumberObjectType = '53' // 'ClassificationValuation'

  or ChangeNumberObjectType = '54' // 'VariantConfigurationObjDpndcy'

  or ChangeNumberObjectType = '55' // 'VariantConfigurationProfile'

  or ChangeNumberObjectType = '63' // 'VariantConfigurationVariantTbl'

  or ChangeNumberObjectType = '83' // 'Recipe'

  or ChangeNumberObjectType = '08' // 'WBSBOM'