I_CentralRequestForQuotationTP

@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'ICNTRLRFQHDRTP'
@EndUserText.label: 'Transactional processing view for Central RFQ Header'
@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel:{compositionRoot: true,
              createEnabled: true,
              deleteEnabled: 'EXTERNAL_CALCULATION',
              semanticKey: 'CentralRequestForQuotation' ,
              transactionalProcessingEnabled: true,
              writeDraftPersistence: 'CNTRLRFQHDR_D',
              writeActivePersistence: 'ICNTRLRFQHDRTP',
              draftEnabled: true ,
              updateEnabled:'EXTERNAL_CALCULATION',
              usageType.dataClass: #TRANSACTIONAL,
              usageType.serviceQuality: #C,
              usageType.sizeCategory: #L,
              entityChangeStateId:'LastChangeDateTime'}
              
              

//@ObjectModel.representativeKey: 'CentralRequestForQuotation'


define view I_CentralRequestForQuotationTP
  as select from R_CentralRequestForQuotation as Document
  association [1..*] to I_CentralReqForQuotationItemTP as _CentralReqForQuotationItemTP on _CentralReqForQuotationItemTP.CentralRequestForQuotation = $projection.CentralRequestForQuotation
  association [1..*] to I_CntrlReqForQuotationBidderTP as _CntrlReqForQuotationBidderTP on _CntrlReqForQuotationBidderTP.CentralRequestForQuotation = $projection.CentralRequestForQuotation
  association [0..*] to I_CentralSupplierQuotationTP   as _CentralSupplierQuotationTP   on _CentralSupplierQuotationTP.CentralRequestForQuotation = $projection.CentralRequestForQuotation
  --Extension Association
  association [0..1] to E_PurchasingDocument           as _CentralReqForQuotationExtn   on _CentralReqForQuotationExtn.PurchasingDocument = $projection.CentralRequestForQuotation
{
      @ObjectModel: { readOnly: true }
  key Document.CentralRequestForQuotation,

      Document.CompanyCode,

      Document.PurchasingDocumentCategory,

      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
      Document.PurchasingDocumentType,

      @ObjectModel: { readOnly: true }
      Document.CreatedByUser,

      @ObjectModel: { readOnly: true }
      Document.CreationDate,

      @ObjectModel: { readOnly: true }
      Document.LastChangeDateTime,

      Document.Language,

      Document.PurchasingOrganization,

      Document.PurchasingGroup,

      Document.DocumentCurrency,

      Document.IncotermsClassification,

      Document.IncotermsTransferLocation,

      Document.IncotermsVersion,

      Document.IncotermsLocation1,

      Document.IncotermsLocation2,

      Document.PaymentTerms,

      Document.CashDiscount1Days,

      Document.CashDiscount2Days,

      Document.CashDiscount1Percent,

      Document.CashDiscount2Percent,

      Document.NetPaymentDays,

      @ObjectModel: { readOnly: true }
      Document.RFQPublishingDate,

      Document.QuotationLatestSubmissionDate,

      Document.BindingPeriodValidityEndDate,

      Document.TargetAmount,

      Document.CorrespncInternalReference,


      @ObjectModel: { readOnly: true }
      Document.RFQLifecycleStatus,

      //      Document.Criticality,


      Document.RequestForQuotationName,

      Document.QuotationEarliestSubmsnDate,

      Document.LatestRegistrationDate,

      Document.FollowOnDocumentCategory,

      Document.PurgDocFollowOnDocumentType as FollowOnDocumentType,

      Document.PurContrValidityStartDate,

      Document.PurContrValidityEndDate,
      @ObjectModel: { readOnly: true }
      Document.PurchasingDocumentDeletionCode,
      @ObjectModel: { readOnly: true }
      Document.IsEndOfPurposeBlocked,

      /*Association*/
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CentralReqForQuotationItemTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlReqForQuotationBidderTP,

      _CentralSupplierQuotationTP,

      Document._CompanyCode,

      Document._DocumentCurrency,

      Document._IncotermsClassification,

      Document._IncotermsVersion,

      Document._PaymentTerms,

      Document._PurchasingDocumentType,

      Document._PurchasingGroup,

      Document._PurchasingOrganization,

      Document._PurchasingDocumentCategory,

      Document._Language,

      Document._CreatedByUser,

      Document._RFQLifecycleStatus,

      Document._FollowOnDocumentType,

      Document._FollowOnDocumentCategory,

      Document._RFQType

}