I_CePuCoDistributedContrTP

@AbapCatalog.sqlViewName: 'ICEPUCODISTROA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Distributed OA for Cntrl Pur Contr - TP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.createEnabled: false
@ObjectModel.updateEnabled:false
@ObjectModel.deleteEnabled: false
//@ObjectModel.draftEnabled: true

@VDM.viewType:#TRANSACTIONAL
@ObjectModel.writeDraftPersistence: 'CNTRLPCDISTROA_D'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #REQUIRED
define view I_CePuCoDistributedContrTP as select from I_CntrlPurContrDistribution 
association [1..1] to I_CentralPurchaseContractTP as _CentralPurchaseContractTP    on  _CentralPurchaseContractTP.CentralPurchaseContract = $projection.CentralPurchaseContract
association [0..1] to I_PurgDocumentCategoryText  as _Text                         on  $projection.PurchasingDocumentCategory = _Text.PurchasingDocumentCategory
                                                                                  and  _Text.Language                         = $session.system_language
association [1..1] to I_CePuCoDistrdContrPaytTrmsTP as _CCTRDistributedContrPayTerms     on _CCTRDistributedContrPayTerms.CentralPurchaseContract = $projection.CentralPurchaseContract
                                                                                        and _CCTRDistributedContrPayTerms.ExtContractForPurg = $projection.ExtContractForPurg 
                                                                                        and _CCTRDistributedContrPayTerms.ProcurementHubSourceSystem = $projection.ProcurementHubSourceSystem 
                                                                                        and _CCTRDistributedContrPayTerms.CompanyCode = $projection.CompanyCode
                                                                                        and _CCTRDistributedContrPayTerms.PurchasingOrganization = $projection.PurchasingOrganization
                                                                                        and _CCTRDistributedContrPayTerms.PurchasingGroup = $projection.PurchasingGroup
                                                                                        and _CCTRDistributedContrPayTerms.DistrResponseMessageUUID = $projection.DistrResponseMessageUUID
                                                                                        and _CCTRDistributedContrPayTerms.PurchasingDocumentCategory = $projection.PurchasingDocumentCategory
                                                                                        and _CCTRDistributedContrPayTerms.DistributionKey = $projection.DistributionKey
                                                                                        and _CCTRDistributedContrPayTerms.CentralPurchaseContractItem = $projection.CentralPurchaseContractItem
                                                                                        
   {
  key    CentralPurchaseContract,
  key    ExtContractForPurg,
  key    ProcurementHubSourceSystem,   
  key    CompanyCode,       
         @ObjectModel.text.element: 'PurchasingDocumentCategoryName'
  key    PurchasingOrganization,
  key    PurchasingGroup,
  key    DistrResponseMessageUUID,  
  key    PurchasingDocumentCategory,
  key    DistributionKey ,
  key    CentralPurchaseContractItem,
         CntrlPurContrDistrTrggrDteTime,
         @Semantics.text
         _Text.PurchasingDocumentCategoryName,
         PurgDocItemDistributionStatus,
         SourceListIsUpdated,
         SrceListResponseMsgUUID,         
         SourceListChangeConfStatus,                       
         LogicalSystem,
         
       @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _CentralPurchaseContractTP,
      
      
     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CCTRDistributedContrPayTerms
}
where
  CentralPurchaseContractItem != '00000' and
  CntrlPurContrItmDistrIsBlocked !='X' and
  ( ExtContractForPurg is not initial or ( IsDeleted is initial and OutlineAgrmtItmIsBlocked is initial ) )
group by
  CentralPurchaseContract,
  CompanyCode,
  DistributionKey,
  CentralPurchaseContractItem,
  ExtContractForPurg,
  LogicalSystem,
  PurchasingDocumentCategory,
  _Text.PurchasingDocumentCategoryName,
  PurchasingOrganization,
  PurchasingGroup,
  PurgDocItemDistributionStatus,
  DistrResponseMessageUUID,
  SourceListIsUpdated,
  SrceListResponseMsgUUID,
  _Text.PurchasingDocumentCategoryName,
  SourceListChangeConfStatus,
//  _SourceListChgConfStsDesc.SourceListChgConfStsDesc,

  ProcurementHubSourceSystem,
  CntrlPurContrDistrTrggrDteTime