I_CapacityShift

@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #M, dataClass: #MASTER }
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Ent Resource Capacity Interval Shift'
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'AvailableCapacityShift'
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.sapObjectNodeType.name: 'EntRsceCapacityIntervalShift'
define view entity I_CapacityShift
  as select from I_WorkCenterCapacityShift_2 as Shift
    inner join   I_CapacityBasic  as PooledCapHeader on Shift.CapacityInternalID = PooledCapHeader.CapacityInternalID
    association [1..1] to I_CapacityBasic   as _EntRsceCapacity   on $projection.CapacityInternalID = _EntRsceCapacity.CapacityInternalID
{     @ObjectModel.foreignKey.association: '_Capacity'
  key Shift.CapacityInternalID,
      @ObjectModel.foreignKey.association: '_AvailableCapacityType'
  key Shift.CapacityActiveVersion,
      @ObjectModel.foreignKey.association: '_EndDate'
  key Shift.IntervalEndDate,
      @ObjectModel.foreignKey.association: '_WeekDay'
  key Shift.WeekDay,
  key cast(coalesce(Shift.AvailableCapacityShift,'0')as schichtnr preserving type ) as AvailableCapacityShift,
      Shift.IntervalStartDate,
      Shift.WorkDayRule,
      Shift.ShiftDefinition,
      Shift.ShiftStartTime,
      Shift.ShiftEndTime,
      Shift.ShiftDefValidityStartDate,
      Shift.ShiftDefValidityEndDate,
      Shift.CapacityNumberOfCapacities,
      Shift.CapacityPlanUtilizationPercent,
      Shift.CapacityBreakDuration,
      Shift.OperatingDurationInSeconds,
      Shift.TotOperatingDurationInSeconds,
      Shift.CapacityLastChangeDateTime,
      /* Associations */
      Shift._Capacity,
      _EntRsceCapacity,
      Shift._AvailableCapacityType,
      Shift._EndDate,
      Shift._WeekDay
}