I_CapacityBySemanticKey

//@AbapCatalog.sqlViewName: 'ICAPABYSEMKEY'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
--@Analytics.dataExtraction.enabled: true
//@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'Capacity'
@ObjectModel.semanticKey: ['Plant', 'Capacity']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #MASTER}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Capacity Header by Semantic Key'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
//define view I_CapacityBySemanticKey

define view entity I_CapacityBySemanticKey
  as select from I_Capacity as kako

  association [1..1] to I_Capacity as _Capacity           on $projection.CapacityInternalID = _Capacity.CapacityInternalID
  association [0..1] to I_Capacity as _ReferencedCapacity on $projection.ReferencedCapacityInternalID = _ReferencedCapacity.CapacityInternalID  
  
{
      // Semantic Key

      @ObjectModel.foreignKey.association: '_Plant'
  key kako.Plant,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key kako.Capacity,

      // Internal Key

      @ObjectModel.foreignKey.association: '_Capacity'
      kako.CapacityInternalID,

      // Attributes

      @ObjectModel.foreignKey.association: '_CapacityCategory'
      kako.CapacityCategoryCode,
      kako.CapacityActiveVersion,
      kako.CapacityIsFinite,
      kako.CapacityIsPooled,
      kako.CapacityHasIndivCapacities,
      kako.CapacityIsExcldFrmLongTermPlng,
      kako.CapacityNumberOfCapacities,
      @ObjectModel.foreignKey.association: '_CapacityResponsiblePlanner'
      kako.CapacityResponsiblePlanner,
      kako.CapacityPlanUtilizationPercent,
      kako.CapacityBreakDuration,
      kako.CapIsUsedInMultiOperations,
      @ObjectModel.foreignKey.association: '_ReferencedCapacity'
      kako.ReferencedCapacityInternalID,
      kako.CapOverloadThresholdInPercent,

      // Assignments

      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      kako.FactoryCalendar,
--    @ObjectModel.foreignKey.association: '_AuthorizationGroup'
      kako.AuthorizationGroup,
      @ObjectModel.foreignKey.association: '_ShiftGrouping'
      kako.ShiftGroup,

      // Times (internal in seconds)

--    kako.CapacityStartTime,
---   kako.CapacityEndTime,

      // Unit of Measures

//      @Semantics.unitOfMeasure: true

      kako.CapacityQuantityUnit,
//      @Semantics.unitOfMeasure: true

      kako.CapacityBaseQtyUnit,

      @Semantics.systemDateTime.lastChangedAt: true
      kako.CapacityLastChangeDateTime,

      //Associations

      _Plant,
      _Capacity,
      _CapacityCategory,
      _FactoryCalendar,
      _CapacityResponsiblePlanner,
      _ShiftGrouping,
      _CapacityQuantityUnit,
      _CapacityBaseQtyUnit,
      _ReferencedCapacity,
      _Text,
      _ReferencedCapacityText
}
where kako.Capacity != '';