I_CFinPurgDocAccountAssignment

@EndUserText.label: 'CFin Purchasing Doc: Account Assignment'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName: 'ICFINPOACC',
  compiler.compareFilter: true,
  preserveKey: true
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck: #NOT_REQUIRED,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view I_CFinPurgDocAccountAssignment
  as select from I_PurgDocAccountAssignment as PurgDocAcctAssgmt
    inner join   I_PurchasingDocument       as PurchasingDocument     on PurgDocAcctAssgmt.PurchasingDocument = PurchasingDocument.PurchasingDocument
    inner join   I_PurchasingDocumentItem   as PurchasingDocumentItem on  PurgDocAcctAssgmt.PurchasingDocument     = PurchasingDocumentItem.PurchasingDocument
                                                                      and PurgDocAcctAssgmt.PurchasingDocumentItem = PurchasingDocumentItem.PurchasingDocumentItem


  association [1..1] to I_CFinPurchasingDocument       as _CFinPurchasingDocument       on  $projection.CFinPurchasingDocument = _CFinPurchasingDocument.CFinPurchasingDocument
                                                                                        and $projection.SenderLogicalSystem    = _CFinPurchasingDocument.SenderLogicalSystem

  association [1..1] to I_CFinPurchasingDocumentItem   as _CFinPurchasingDocumentItem   on  $projection.SenderLogicalSystem        = _CFinPurchasingDocumentItem.SenderLogicalSystem
                                                                                        and $projection.CFinPurchasingDocument     = _CFinPurchasingDocumentItem.CFinPurchasingDocument
                                                                                        and $projection.CFinPurchasingDocumentItem = _CFinPurchasingDocumentItem.CFinPurchasingDocumentItem

  association [0..1] to I_CentralFinanceSalesDocument  as _CFinSalesDocument            on  $projection.CentralFinanceSalesDocument = _CFinSalesDocument.CentralFinanceSalesDocument
                                                                                        and $projection.SenderLogicalSystem         = _CFinSalesDocument.SenderLogicalSystem

  association [0..1] to I_CFinSalesDocumentItem        as _CFinSalesDocumentItem        on  $projection.CentralFinanceSalesDocument = _CFinSalesDocumentItem.CentralFinanceSalesDocument
                                                                                        and $projection.CFinSalesDocumentItem       = _CFinSalesDocumentItem.CFinSalesDocumentItem
                                                                                        and $projection.SenderLogicalSystem         = _CFinSalesDocumentItem.SenderLogicalSystem

  association [0..1] to I_CFinRpldSalesDocScheduleLine as _CFinRpldSalesDocScheduleLine on  $projection.CentralFinanceSalesDocument  = _CFinRpldSalesDocScheduleLine.CFinReplicatedSalesDocument
                                                                                        and $projection.CFinSalesDocumentItem        = _CFinRpldSalesDocScheduleLine.CFinRpldSalesDocumentItem
                                                                                        and $projection.CFinRpldSalesDocScheduleLine = _CFinRpldSalesDocScheduleLine.CFinRpldSalesDocScheduleLine
                                                                                        and $projection.SenderLogicalSystem          = _CFinRpldSalesDocScheduleLine.SenderLogicalSystem

  association [0..1] to I_WBSElementBasicData          as _WBSElementBasicData          on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID

  association [0..1] to I_WBSElementBasicDataStdVH     as _WBSElementBasicDataStdVH     on  $projection.WBSElementInternalID = _WBSElementBasicDataStdVH.WBSElementInternalID

  association [0..1] to I_LogicalSystem                as _LogicalSystem                on  $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem

  association [0..1] to I_UnitOfMeasure                as _OrderQuantityUnit            on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure

  association [0..1] to I_Currency                     as _DocumentCurrency             on  $projection.DocumentCurrency = _DocumentCurrency.Currency


{
          @ObjectModel.foreignKey.association: '_LogicalSystem'
  key     cast( '          ' as logsys preserving type  )                                                    as SenderLogicalSystem,
          @ObjectModel.foreignKey.association: '_CFinPurchasingDocument'
  key     cast( PurgDocAcctAssgmt.PurchasingDocument  as fins_cfin_av_purchasing_doc preserving type )       as CFinPurchasingDocument,
          @ObjectModel.foreignKey.association: '_CFinPurchasingDocumentItem'
  key     cast( PurgDocAcctAssgmt.PurchasingDocumentItem as fins_cfin_av_purg_document_itm preserving type ) as CFinPurchasingDocumentItem,
  key     cast(AccountAssignmentNumber as fins_cfin_av_purg_doc_acctasgt preserving type  )                  as CFinPurgDocAccountAssignment,
          PurgDocAcctAssgmt.IsDeleted,
          @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
          PurgDocAcctAssgmt.Quantity,
          PurgDocAcctAssgmt.MultipleAcctAssgmtDistrPercent,
          @Semantics.amount.currencyCode: 'DocumentCurrency'
          PurgDocAcctAssgmt.PurgDocNetAmount,
          @ObjectModel.foreignKey.association: '_GLAccount'
          @Consumption.valueHelp: '_MM_GLAccountVH'
          PurgDocAcctAssgmt.GLAccount,
          @ObjectModel.foreignKey.association: '_BusinessArea'
          @ObjectModel.text.association: '_BusinessAreaText'
          PurgDocAcctAssgmt.BusinessArea,
          @ObjectModel.foreignKey.association: '_CostCenter'
          @ObjectModel.text.association: '_CostCenterText'
          @Consumption.valueHelp: '_MM_CostCenterValueHelp'
          PurgDocAcctAssgmt.CostCenter,
          @ObjectModel.foreignKey.association: '_CFinSalesDocument'
          PurgDocAcctAssgmt.SalesOrder                                                                       as CentralFinanceSalesDocument,
          @ObjectModel.foreignKey.association: '_CFinSalesDocumentItem'
          PurgDocAcctAssgmt.SalesOrderItem                                                                   as CFinSalesDocumentItem,
          @ObjectModel.foreignKey.association: '_CFinRpldSalesDocScheduleLine'
          PurgDocAcctAssgmt.SalesOrderScheduleLine                                                           as CFinRpldSalesDocScheduleLine,
          @ObjectModel.foreignKey.association: '_FixedAsset'
          PurgDocAcctAssgmt.MasterFixedAsset,
          @ObjectModel.foreignKey.association: '_FixedAsset'
          PurgDocAcctAssgmt.FixedAsset,
          PurgDocAcctAssgmt.OrderID,
          @ObjectModel.foreignKey.association: '_ControllingArea'
          PurgDocAcctAssgmt.ControllingArea,
          @ObjectModel.foreignKey.association: '_WBSElementBasicData'
          @Consumption.valueHelp: '_WBSElementBasicDataStdVH'
          cast( PurgDocAcctAssgmt.WBSElementInternalID as ps_s4_pspnr preserving type )                      as WBSElementInternalID,
          PurgDocAcctAssgmt.ProjectNetwork,
          PurgDocAcctAssgmt.ProjectNetworkInternalID,
          PurgDocAcctAssgmt.RealEstateObject,
          PurgDocAcctAssgmt.NetworkActivityInternalID,
          @Consumption.valueHelp: '_FundsCenterStdVH'
          PurgDocAcctAssgmt.FundsCenter,
          @Consumption.valueHelp: '_FundStdVH'
          PurgDocAcctAssgmt.Fund,
          @ObjectModel.foreignKey.association: '_FunctionalArea'
          @ObjectModel.text.association: '_FunctionalAreaText'
          @Consumption.valueHelp: '_FndsMgmtFuncnlAreaStdVH'
          PurgDocAcctAssgmt.FunctionalArea,
          PurgDocAcctAssgmt.SettlementReferenceDate,
          PurgDocAcctAssgmt.NonDeductibleInputTaxAmount,
          @ObjectModel.foreignKey.association: '_CostCenterActivityType'
          @ObjectModel.text.association: '_CostCenterActivityTypeText'
          PurgDocAcctAssgmt.CostCtrActivityType,
          @Consumption.valueHelp: '_BudgetPeriodStdVH'
          PurgDocAcctAssgmt.GrantID,
          PurgDocAcctAssgmt.BudgetPeriod,
          PurgDocAcctAssgmt.GoodsRecepientName,
          PurgDocAcctAssgmt.ValidityDate,
          PurgDocAcctAssgmt.ChartOfAccounts,
          @Semantics.unitOfMeasure: true
          @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
          PurchasingDocumentItem.OrderQuantityUnit,
          @Semantics.currencyCode:true
          @ObjectModel.foreignKey.association: '_DocumentCurrency'
          PurchasingDocument.DocumentCurrency,
          PurgDocAcctAssgmt.ProfitCenter,


          _CFinPurchasingDocument,
          _CFinPurchasingDocumentItem,
          _CFinSalesDocument,
          _CFinSalesDocumentItem,
          _CFinRpldSalesDocScheduleLine,
          _LogicalSystem,
          _CostCenter,
          _BusinessArea,
          _ControllingArea,
          _GLAccount,
          _WBSElementBasicData,
          _FunctionalArea,
          _CostCenterActivityType,
          _FixedAssetWorklist,
          _FixedAsset,
          _CostCenterText,
          _GLAccountText,
          _BusinessAreaText,
          _FunctionalAreaText,
          _CostCenterActivityTypeText,
          _FundStdVH,
          _BudgetPeriodStdVH,
          _FundsCenterStdVH,
          _FndsMgmtFuncnlAreaStdVH,
          _MM_CostCenterValueHelp,
          _WBSElementBasicDataStdVH,
          _MM_GLAccountVH,
          _OrderQuantityUnit,
          _DocumentCurrency,
          _ProfitCenter
}