I_CADocumentCube

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics: { dataCategory: #CUBE,
              internalName: #LOCAL,
              dataExtraction: { enabled: true,
                                delta.changeDataCapture: { mapping:[ { table           : 'dfkkko',role: #MAIN,
                                                                       viewElement     : ['CADocumentNumber' ],
                                                                       tableElement    : ['opbel' ] } ] } } }

@EndUserText.label: 'Contract Accounting Document - Cube'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{ modelingPattern: #ANALYTICAL_CUBE,
               sapObjectNodeType.name: 'ContrAcctgDocument',
               supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #EXTRACTION_DATA_SOURCE,
                                        #ANALYTICAL_PROVIDER  ],
               usageType:{ serviceQuality: #C,
                           sizeCategory: #XXL,
                           dataClass: #TRANSACTIONAL } }

@VDM.viewType: #COMPOSITE

define view entity I_CADocumentCube
  as select from I_CADocument
  
  // Key User Extensibility. Is registerd in transaction SCFD_REGISTRY. Do not change E_CADocumentHeader or alias _Extension without adopting CFD regestry entry

  association [1..1] to E_CADocumentHeader as _Extension on  $projection.CADocumentNumber = _Extension.CADocumentNumber

{
  key CADocumentNumber,
      CreatedByUser,
      CreationDate,
      CreationTime,
      @ObjectModel.foreignKey.association: '_CompCode'
      CATaxCompanyCode,
      CAStorageLocationOfTaxSuplmnt,
      CATaxCodeWasExchanged,
      TaxReportingDate,
      CAReconciliationKey,
      CASeparateDocIsCreatedInGL,
      CARequestedPeriodForGLTransfer,
      @ObjectModel.foreignKey.association: '_ApplArea'
      CAApplicationArea,
      @ObjectModel.foreignKey.association: '_DocType'
      CADocumentType,
      @ObjectModel.foreignKey.association: '_DocOriginCode'
      CADocumentOriginCode,
      @ObjectModel.foreignKey.association: '_Currency'
      TransactionCurrency,
      DocumentDate,
      CAPostingDate,
      ExchangeRateDate,
      CAReferenceDocument,
      CAReturnReason,
      CAPostingReason,
      ReferenceDocumentType,
      OriginalReferenceDocument,
      CAReversedDocumentNumber,
      CAClearingInformation,
      CAReversalDocumentNumber,
      CADocumentSupplements,
      LogicalSystem,
      @ObjectModel.foreignKey.association: '_WorkflowCheckReason'
      CAWorkflowCheckReason,
      @ObjectModel.foreignKey.association: '_WorkflowCheckProcess'
      CAWorkflowCheckProcess,
      CADocumentTransactionClass,
      CADocContainsCashFlowItems,
      CADocumentClass,
      CADocumentVersion,
      IsIndividualPosting,
      CADocumentIsAged,

      /* Associations */
      _CAApplicationArea      as _ApplArea,
      _CADocumentOriginCode   as _DocOriginCode,
      _CADocumentType         as _DocType,
      _CATaxCompanyCode       as _CompCode,
      _CAWorkflowCheckProcess as _WorkflowCheckProcess,
      _CAWorkflowCheckReason  as _WorkflowCheckReason,
      _TransactionCurrency    as _Currency
}