I_CADocumentBPItemPaymentData

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Document BP Item Payment Data'

@ObjectModel: { modelingPattern: #NONE,
                //sapObjectNodeType.name: 'ContrAcctgDocBusPartItmPaytDta',

                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE ],
                usageType: { dataClass: #TRANSACTIONAL,
                             serviceQuality: #A,
                             sizeCategory: #XL } }

@VDM.viewType: #BASIC

define view entity I_CADocumentBPItemPaymentData
  as select from dfkkopc

  association [0..1] to I_CAAuthorizationType    as _CAAuthorizationType    on $projection.CAAuthorizationType = _CAAuthorizationType.CAAuthorizationType
  association [1..1] to I_CADocument             as _CADocument             on $projection.CADocumentNumber = _CADocument.CADocumentNumber
  association [0..1] to I_CACreditPostingOrigin  as _CACreditPostingOrigin  on $projection.OriginalSourceOfCredit = _CACreditPostingOrigin.OriginalSourceOfCredit
  association [1..1] to I_Currency               as _AuthorizationCurrency  on $projection.AuthorizationCurrency = _AuthorizationCurrency.Currency
  association [1..1] to I_PaytServiceProviderIdn as _PaymentServiceProvider on $projection.PaymentServiceProvider = _PaymentServiceProvider.PaymentServiceProvider

{
      @ObjectModel.foreignKey.association: '_CADocument'
  key opbel           as CADocumentNumber,
  key pygrp           as CAGroupingForPayment,

      ccins           as PaymentCardType,
      ccnum           as PaytCardByDigitalPaymentSrvc,
      ccfol           as PaymentCardSequenceNumber,
      datab           as PaymentCardValidityStartDate,
      datbi           as PaymentCardValidityEndDate,
      ccname          as PaymentCardHolderName,
      masked_id       as PaymentCardMaskedNumber,
      //cvval,

      //cvvct,

      //cvvst,


      aunum           as CAAuthznByDigitalPaytSrvc,
      autra           as CAAuthorizationByAcquirer,
      audat           as AuthorizationDate,
      autim           as AuthorizationTime,
      @ObjectModel.foreignKey.association: '_CAAuthorizationType'
      auart           as CAAuthorizationType,
      @Semantics.amount.currencyCode: 'AuthorizationCurrency'
      autwr           as AuthorizedAmountInAuthznCrcy,
      @ObjectModel.foreignKey.association: '_AuthorizationCurrency'
      ccwae           as AuthorizationCurrency,
      merch           as CAPaytServiceProviderMerchant,
      expdt           as AuthorizationExpirationDate,
      exptm           as AuthorizationExpirationTime,
      //extmp,

      //autmp,

      aucid           as CAPaymentIDAuthznWithBilling,
      avref           as CASettlementPaymentAdviceRef,
      dp_auth_rel_id  as PaymentCardAuthznRelationID,
      dp_fraud_risk   as DigitalPaymentFraudRisk,

      cguid           as PaymentCardUUID,
      enctp           as EncryptionType,
      xguid           as CAKeyForPaymentCardSupplement,
      //srqid,


      @ObjectModel.foreignKey.association: '_PaymentServiceProvider'
      pays_prov       as PaymentServiceProvider,
      pays_tran       as PaymentRefByPaytSrvcProvider,
      orig_pays_tran  as OriglPaytRefByPaytSrvcProvider,
      @ObjectModel.foreignKey.association: '_CACreditPostingOrigin'
      orig_credit     as OriginalSourceOfCredit,

      dp_payment_type as DigitalPaymentType,
      dp_trans_id     as PaymentByDigitalPaymentService,
      //_dataaging,


      //iban         as SEPAMandateSenderIBAN,

      //swift        as SEPAMandateSenderBankSWIFTCode,

      //koinh_ip,

      //txtvw,

      //meref_ip,

      //bkref_ip,

      //pyref_ip,


      _AuthorizationCurrency,
      _CAAuthorizationType,
      _CACreditPostingOrigin,
      _CADocument,
      _PaymentServiceProvider,

      /* deprecated fields */
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'CAPaytServiceProviderMerchant'
      merch           as MerchantByClearingHouse      
}