I_CACompanyCodeAddlCurrency

@AbapCatalog.viewEnhancementCategory: [#NONE]

@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Additional Currencies for Company Code'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{ serviceQuality: #C,
                         sizeCategory: #S,
                         dataClass: #CUSTOMIZING }

@VDM.viewType: #COMPOSITE




// DO NOT USE!!

// Please use I_AdditionalCurrencyRoles instead






define view entity I_CACompanyCodeAddlCurrency
  as select from I_CompanyCode as CompanyCode

  association [0..1] to FINS_T001A  as _CompanyCurrencyControl on $projection.CompanyCode = _CompanyCurrencyControl.bukrs
  association [0..1] to I_SAPClient as _SAPClient              on _SAPClient.SAPClientName is not initial
  association [0..1] to t005        as _Country                on CompanyCode.Country = _Country.land1
  association [0..1] to t880        as _GlobalCompanyData      on CompanyCode.Company = _GlobalCompanyData.rcomp

  association [0..1] to I_Currency  as _AdditionalCurrency1    on $projection.AdditionalCurrency1 = _AdditionalCurrency1.Currency
  association [0..1] to I_Currency  as _AdditionalCurrency2    on $projection.AdditionalCurrency2 = _AdditionalCurrency2.Currency

{
  key CompanyCode,

      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'
      cast( case _CompanyCurrencyControl.curtp
          when '11' then CompanyCode.Currency
          when '12' then CompanyCode.Currency
          when '30' then _SAPClient.GroupCurrency
          when '31' then _SAPClient.GroupCurrency
          when '32' then _SAPClient.GroupCurrency
          when '40' then _Country.curha
          when '50' then _Country.curin
          when '60' then _GlobalCompanyData.curr
          else ''
      end as fis_hwae2 ) as AdditionalCurrency1,

      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      cast( case _CompanyCurrencyControl.curtp2
          when '11' then CompanyCode.Currency
          when '12' then CompanyCode.Currency
          when '30' then _SAPClient.GroupCurrency
          when '31' then _SAPClient.GroupCurrency
          when '32' then _SAPClient.GroupCurrency
          when '40' then _Country.curha
          when '50' then _Country.curin
          when '60' then _GlobalCompanyData.curr
          else ''
      end as fis_hwae3 ) as AdditionalCurrency2,

      /* associations */
      _AdditionalCurrency1,
      _AdditionalCurrency2
}