I_BusinessProcessDetail

@EndUserText.label: 'Business Process Detail'
@ObjectModel.representativeKey: 'BusinessProcess'
@Analytics: { dataCategory: #DIMENSION } //dataExtraction.enabled: true }

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFIBUSPROCESSD'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER

@Metadata.allowExtensions:true
define view I_BusinessProcessDetail
  as select from cbpr
  association [0..*] to I_BusinessProcessText as _Text            on  $projection.ControllingArea = _Text.ControllingArea
                                                                  and $projection.BusinessProcess = _Text.BusinessProcess
//                                                                and $projection.ValidityEndDate = _Text.ValidityEndDate

  association [1]    to I_ControllingArea     as _ControllingArea on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1]    to I_CompanyCode         as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1]    to I_BusinessArea        as _BusinessArea    on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_CostCenter          as _CostCenter      on  $projection.ControllingObject = _CostCenter.ControllingArea
                                                                  and $projection.CostCenter        = _CostCenter.CostCenter
  association [0..*] to I_ProfitCenter        as _ProfitCenter    on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                  and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..1] to I_ControllingObject   as _ControllingObject on  $projection.ControllingObject = _ControllingObject.ControllingObject
                                                                  
{

      @ObjectModel.foreignKey.association: '_ControllingArea'
  key cast( kokrs as fis_kokrs )        as ControllingArea,
      @ObjectModel.text.association: '_Text'
  key prznr                             as BusinessProcess,
      @Semantics.businessDate.to: true
  key datbi                             as ValidityEndDate,
      @Semantics.businessDate.from: true
      datab                             as ValidityStartDate,
      erfdt                             as CreationDate,
      erfnm                             as CreatedByUser,
      aennm                             as LastChangedByUser,
      @ObjectModel.foreignKey.association: '_ControllingObject'
      objnr                             as ControllingObject,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      bukrs                             as CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      gsber                             as BusinessArea,
      werks                             as Plant,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      prctr                             as ProfitCenter,
      vkorg                             as SalesOrganization,
      vtweg                             as DistributionChannel,
      spart                             as Division,
      @ObjectModel.foreignKey.association: '_CostCenter'
      kostl                             as CostCenter,
      kalsm                             as CostingSheet,
      logsystem                         as LogicalSystem,
      vksta                             as AllocationCostElement,

      _Text,
      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _CostCenter,
      _ProfitCenter,
      _ControllingObject

};