I_BusinessPartnerRoleGov

@AbapCatalog.sqlViewName: 'IBPROLEGOV'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'BP Roles with RAP (Governance)'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
//@Analytics.dataCategory: #DIMENSION

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
define view I_BusinessPartnerRoleGov
  as select from I_BusinessPartnerRoleProc
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
  
  association [0..1] to I_BusinessPartnerRole     as _BusinessPartnerRole     on  $projection.BusinessPartnerRole = _BusinessPartnerRole.BusinessPartnerRole
  association [0..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
      @Consumption.valueHelp: '_BusinessPartnerRole'
  key BusinessPartnerRole,

      BusinessPartner,
      ValidFrom,
      ValidTo,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      )                                           as MasterDataIsCurrent,
      _BusinessPartnerRole,
      //      AuthorizationGroup,

      _BusinessPartnerGov
} where MDChgProcessSourceModified <> 'D'

union all

select from I_BusinessPartner_to_BP_Role
association [0..1] to I_BusinessPartnerRole as _BusinessPartnerRole on  $projection.BusinessPartnerRole = _BusinessPartnerRole.BusinessPartnerRole
association [0..1] to I_BusinessPartnerGov  as _BusinessPartnerGov  on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                    and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                    and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                    and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
      @Consumption.valueHelp: '_BusinessPartnerRole'
  key BusinessPartnerRole,

      BusinessPartner,
      ValidFrom,
      ValidTo,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,
      _BusinessPartnerRole,
      //      AuthorizationGroup,

      _BusinessPartnerGov
}