I_BusinessPartnerRatingTP

@ObjectModel: {usageType: { dataClass: #TRANSACTIONAL,
                             serviceQuality: #C,
                             sizeCategory: #XL}             
              }
@AccessControl: {authorizationCheck: #MANDATORY,
                 personalData.blocking: #REQUIRED}
@VDM: {viewType: #TRANSACTIONAL,
       lifecycle.contract.type: #SAP_INTERNAL_API}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]         
@EndUserText.label: 'Ratings - TP'

define view entity I_BusinessPartnerRatingTP
  as select from I_BusinessPartnerRating
  association to parent I_BPFinancialServicesTP as _FSBusinessPartner on $projection.BusinessPartner = _FSBusinessPartner.BusinessPartner
  association to I_BusinessPartnerTP_2 as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
{
  key BusinessPartner,
  key BusinessPartnerRatingProcedure,
  key cast ( BPRatingValidityEndDate as abap.char( 17 )) as BPRatingValidityEndDate,
      @ObjectModel.editableFieldFor: 'BusinessPartnerRatingProcedure'
      @ObjectModel.foreignKey.association: '_BPRatingProcedure'
      BusinessPartnerRatingProcedure as BPRatingProcedureForEdit,
      @ObjectModel.editableFieldFor: 'BPRatingValidityEndDate'
      BPRatingValidityEndDate        as BPRatingValidityEndDateForEdit,
      BusinessPartnerRatingGrade,
      BusinessPartnerRatingTrend,
      BPRatingValidityStartDate,
      BPRatingCreationDate,
      BusinessPartnerRatingComment,
      BusinessPartnerRatingIsAllowed,
      BPRatingIsValidOnKeyDate,
      BusinessPartnerRatingKeyDate,
      BusinessPartnerRatingIsExpired,
      BPRatingLongComment,
      
      /* Associations */
      _BPFinancialServicesExtn,
      _BPRatingProcedure,
      _BPRatingProcedureGrade,
      _BPRatingTrend,
      _BusinessPartner,
      _FSBusinessPartner
}