I_BusinessPartnerAddressGov

@AbapCatalog.sqlViewName: 'IBPADDRESSGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Business Partner Address (Governance)'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #COMPOSITE
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusinessPartnerAddressGov
  as select from I_BusinessPartnerAddressProc
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
  association [0..1] to I_BPProtectedAddressGov   as _BPProtectedAddress      on  $projection.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BPProtectedAddress.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BPProtectedAddress.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BPProtectedAddress.MDChgProcessSrceObject
                                                                              and $projection.AddressNumber           = _BPProtectedAddress.AddressNumber
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess

{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
      BusinessPartner,
      ValidityStartDate,
      ValidityEndDate,
      BusinessPartnerAddressUUID,
      CareOfName,
      HouseNumber,
      StreetName,
      HouseNumberSupplementText,
      DistrictName,
      PostalCode,
      CityName,
      Country,
      Region,
      AddressTimeZone,
      TaxJurisdiction,
      TransportZone,
      CompanyPostalCode,
      DeliveryServiceNumber,
      POBox,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      CorrespondenceLanguage,
      PrfrdCommMediumType,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      AdditionalStreetSuffixName,
      Building,
      Floor,
      RoomNumber,
      HomeCityName,
      DeliveryServiceTypeCode,
      MDChgProcessSourceModified,
      CityFileTestStatus,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
      //             else ' '

        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      _BusinessPartnerGov,
      _BPProtectedAddress
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from  I_BusPartAddress as BPAddressLinkActive
  inner join I_Address        as BPAddressActive on BPAddressLinkActive.AddressID = BPAddressActive.AddressID

association [1..1] to I_BusinessPartnerGov    as _BusinessPartnerGov on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                     and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                     and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                     and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject
association [0..1] to I_BPProtectedAddressGov as _BPProtectedAddress on  $projection.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
                                                                     and $projection.MDChgProcessStep        = _BPProtectedAddress.MDChgProcessStep
                                                                     and $projection.MDChgProcessSrceSystem  = _BPProtectedAddress.MDChgProcessSrceSystem
                                                                     and $projection.MDChgProcessSrceObject  = _BPProtectedAddress.MDChgProcessSrceObject
                                                                     and $projection.AddressNumber           = _BPProtectedAddress.AddressNumber
{
  key '000000000000'                                    as MasterDataChangeProcess,
  key '0000'                                            as MDChgProcessStep,
  key ''                                                as MDChgProcessSrceSystem,
  key BPAddressLinkActive.BusinessPartner               as MDChgProcessSrceObject,
  key BPAddressLinkActive.AddressID                     as AddressNumber,

      BPAddressLinkActive.BusinessPartner,
      BPAddressLinkActive.ValidityStartDate,
      BPAddressLinkActive.ValidityEndDate,
      BPAddressLinkActive.AddressUUID                   as BusinessPartnerAddressUUID,
      BPAddressActive.CareOfName,
      BPAddressActive.HouseNumber,
      BPAddressActive.StreetName,
      BPAddressActive.HouseNumberSupplementText,
      BPAddressActive.District                          as DistrictName,
      BPAddressActive.PostalCode,
      BPAddressActive.CityName,
      BPAddressActive.Country,
      BPAddressActive.Region,
      BPAddressActive.AddressTimeZone,
      BPAddressActive.TaxJurisdiction,
      BPAddressActive.TransportZone,
      BPAddressActive.CompanyPostalCode,
      BPAddressActive.DeliveryServiceNumber,
      BPAddressActive.POBox,
      BPAddressActive.POBoxIsWithoutNumber,
      BPAddressActive.POBoxPostalCode,
      BPAddressActive.POBoxLobbyName,
      BPAddressActive.POBoxDeviatingCityName,
      BPAddressActive.POBoxDeviatingRegion,
      BPAddressActive.POBoxDeviatingCountry,
      BPAddressActive.CorrespondenceLanguage,
      BPAddressActive.PrfrdCommMediumType,
      BPAddressActive.StreetPrefixName,
      BPAddressActive.AdditionalStreetPrefixName,
      BPAddressActive.StreetSuffixName,
      BPAddressActive.AdditionalStreetSuffixName,
      BPAddressActive.Building,
      BPAddressActive.Floor,
      BPAddressActive.RoomNumber,
      BPAddressActive.HomeCityName,
      BPAddressActive.DeliveryServiceTypeCode,
      cast( '' as mdc_source_modified preserving type ) as MDChgProcessSourceModified,
      BPAddressActive.CityFileTestStatus,

      cast( 'X' as abap_boolean preserving type )       as MasterDataIsCurrent,

      _BusinessPartnerGov,
      _BPProtectedAddress
}