I_BusinessPartAddress_2

@AbapCatalog.sqlViewName: 'IBPADDR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_Address' ]
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Business Partner Address'
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
define view I_BusinessPartAddress_2
  as select from but020 as BusinessPartnerAddress
    inner join   but000 on but000.partner = BusinessPartnerAddress.partner

  association [1..1] to I_BusinessPartner    as _BusinessPartner    on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_Address_2          as _Address            on  $projection.AddressNumber          = _Address.AddressID
                                                                    and _Address.AddressRepresentationCode is initial
                                                                    and $projection.PersonNumber           = _Address.AddressPersonID
  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                    and $projection.AddressNumber   = _BPProtectedAddress.AddressID
  //  association [0..*] to I_BPDataControllerUsage as _BPDataControllerUsage on  $projection.BusinessPartner = _BPDataControllerUsage.BusinessPartner

{
  key BusinessPartnerAddress.partner                                       as BusinessPartner,
  key BusinessPartnerAddress.addrnumber                                    as AddressNumber,

      BusinessPartnerAddress.addr_valid_from                               as ValidityStartDate,
      BusinessPartnerAddress.addr_valid_to                                 as ValidityEndDate,
      BusinessPartnerAddress.address_guid                                  as BusinessPartnerAddressUUID,
      BusinessPartnerAddress.move_addr                                     as BPTargetAddressID,
      BusinessPartnerAddress.addr_move_date                                as BPAddressMoveDateTime,
      _Address.CareOfName,
      _Address.FormOfAddress,
      _Address.AddresseeFullName                                           as FullName,
      _Address.HouseNumber,
      _Address.StreetName,
      _Address.HouseNumberSupplementText,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'DistrictName'
      _Address.DistrictName                                                as District,
      _Address.DistrictName                                                as DistrictName,
      _Address.PostalCode,
      _Address.CityName,
      _Address.Country,
      _Address.Region,
      _Address.AddressTimeZone,
      _Address.TaxJurisdiction,
      _Address.TransportZone,
      _Address.CompanyPostalCode,
      _Address.DeliveryServiceNumber,
      _Address.POBox,
      _Address.POBoxIsWithoutNumber,
      _Address.POBoxPostalCode,
      _Address.POBoxLobbyName,
      _Address.POBoxDeviatingCityName,
      _Address.POBoxDeviatingRegion,
      _Address.POBoxDeviatingCountry,
      _Address.CorrespondenceLanguage,
      _Address.PrfrdCommMediumType,
      _Address.StreetPrefixName1                                           as StreetPrefixName,
      _Address.StreetPrefixName2                                           as AdditionalStreetPrefixName,
      _Address.StreetSuffixName1                                           as StreetSuffixName,
      _Address.StreetSuffixName2                                           as AdditionalStreetSuffixName,
      _Address.VillageName                                                 as HomeCityName,
      _Address.DeliveryServiceTypeCode,
      _Address.StreetAddrNonDeliverableReason                              as AddressStreetUnusable,
      _Address.POBoxAddrNonDeliverableReason                               as AddressPostBoxUnusable,
      _Address.Building,
      _Address.Floor,
      _Address.RoomNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BPCountyText'
      _Address.SecondaryRegionName                                         as County,
      _Address.SecondaryRegionName                                         as BPCountyText,
      _Address.SecondaryRegion                                             as CountyCode,
      _Address.TertiaryRegion                                              as TownshipCode,
      _Address.TertiaryRegionName                                          as TownshipName,
      _Address.RegionalStructureCheckStatus                                as CityFileTestStatus,

      _Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
      _Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry            as PhoneNumberCountry,
      _Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber          as PhoneNumberExtension,
      _Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber           as FaxNumber,
      _Address._CurrentDfltFaxNumber.FaxNumberCountry                      as FaxCountry,
      _Address._CurrentDfltFaxNumber.FaxExtensionNumber                    as FaxNumberExtension,
      _Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobilePhoneNumber,
      _Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry            as MobilePhoneCountry,
      _Address._CurrentDfltEmailAddress.EmailAddress                       as EmailAddress,
      cast ('00000' as abap.int2 )                                         as URLFieldLength,
      _Address._MainWebsiteURL.UniformResourceIdentifier                   as WebsiteURL,
      but000.persnumber                                                    as PersonNumber,

      ////////////// Start of Datacontroller 10+1 fields -  Not to be consumed by any other views//////////

      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet                                   as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                                     as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                                     as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                                     as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                                     as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                                     as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                                     as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                                     as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                                     as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                                     as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10                                    as DataController10,
      ////////////// End of Datacontroller 10+1 fields//////////

      _Address,
      _BusinessPartner,
      _BPProtectedAddress
      //      _BPDataControllerUsage

}