I_BusinessAreaHierNode

@EndUserText.label: 'BusinessArea Hier Node'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFIBUSAHN'
@Hierarchy.parentChild:
{ recurse:          {   parent: 'ParentNode',   child:  'HierarchyNode'   },
  siblingsOrder:    {   by: 'HierarchyNodeSequence',    direction: 'ASC'   },
  directory:        '_Hierarchy'
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'HierarchyNode'
@ObjectModel.modelingPattern: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
@ObjectModel.supportedCapabilities: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
@AbapCatalog.compiler.compareFilter:true
@Metadata.ignorePropagatedAnnotations:true
@AbapCatalog.preserveKey:true
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL},
  dataCategory: #HIERARCHY
}
@ObjectModel.sapObjectNodeType.name:'BusinessAreaHierarchyNode'

define view I_BusinessAreaHierNode
  as select from hrrp_node_n


  association [0..*] to I_BusinessAreaHierNodeT as _Text         on  $projection.BusinessAreaHierarchy = _Text.BusinessAreaHierarchy
                                                                 and $projection.HierarchyNode         = _Text.HierarchyNode
                                                                 and $projection.BusinessArea          = '' // just to show that this association is only to be followed if FunctionalArea is blank


  association [0..1] to I_BusinessArea          as _BusinessArea on  $projection.BusinessArea = _BusinessArea.BusinessArea

  association [1..1] to I_BusinessAreaHierarchy as _Hierarchy    on  $projection.BusinessAreaHierarchy = _Hierarchy.BusinessAreaHierarchy
                                                                 and $projection.ValidityEndDate       = _Hierarchy.ValidityEndDate


{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(hrrp_node_n.hryid_42 as fis_hryid_businessarea_42 preserving type ) as BusinessAreaHierarchy,
      @ObjectModel.text.association: '_Text'
  key hrrp_node_n.hrynode                                                      as HierarchyNode,
      @Semantics.businessDate.to: true
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
  key cast(hrrp_node_n.hryvalto as fis_datbi preserving type )                 as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast(hrrp_node_n.hryvalfrom as fis_datab preserving type )               as ValidityStartDate,
      hrrp_node_n.parnode                                                      as ParentNode,
      @VDM.lifecycle.status:    #DEPRECATED
      cast( '000000000000001' as hryversn )                                    as HierarchyVersion,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusinessAreaStdVH',
                     element: 'BusinessArea' }
        }]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      hrrp_node_n.gsber                                                        as BusinessArea,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'HierarchyNodeSequence'
      concat(hrrp_node_n.hryseqnbr, hrrp_node_n.hrynode)                       as SequenceNumber, // do not use any longer, use HierarchyNodeSequence

      hrrp_node_n.hryseqnbr                                                    as HierarchyNodeSequence,
      hrrp_node_n.hrylevel                                                     as HierarchyNodeLevel,
      hrrp_node_n.nodetype                                                     as NodeType,
      hrrp_node_n.nodevalue                                                    as HierarchyNodeVal,

      _Text,
      _BusinessArea,
      _Hierarchy

}
where
      hrrp_node_n.nodetype <> 'D'
  and hrrp_node_n.hrytyp   =  'GL04';