I_BusPartWebsiteURLGov

@AbapCatalog.sqlViewName: 'IBPWEBSITEURLGOV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'BP Website URL Governance'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusPartWebsiteURLGov
  as select from I_BusPartWebsiteURLProc
  association [1..1] to I_BusinessPartnerGov      as _BusinessPartner         on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
  association [0..1] to I_BPProtectedAddress      as _BPProtectedAddress      on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      //  key ValidityStartDateTime as ValidityStartDate,

      IsDefaultURLAddress,
      SearchURLAddress,
      cast(
        case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
                  MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
             else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,
      UniformResourceIdentifierType,
      URLFieldLength,
      WebsiteURL,

      _BPProtectedAddress,
      _BusinessPartner
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_BPWebsiteURL
association [1..1] to I_BusinessPartnerGov as _BusinessPartner    on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                  and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                  and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                  and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.MDChgProcessSrceObject = _BPProtectedAddress.BusinessPartner
                                                                  and $projection.AddressNumber          = _BPProtectedAddress.AddressID
{
  key '000000000000'                              as MasterDataChangeProcess,
  key '0000'                                      as MDChgProcessStep,
  key ''                                          as MDChgProcessSrceSystem,
  key BusinessPartner                             as MDChgProcessSrceObject,
  key AddressID                                   as AddressNumber,
      //  key Person,

  key OrdinalNumber,
      //  key ValidityStartDate,

      IsDefaultURLAddress,
      SearchURLAddress,
      cast( 'X' as abap_boolean preserving type ) as MasterDataIsCurrent,
      UniformResourceIdentifierType,
      cast ( URLFieldLength as   ad_urilng )      as URLFieldLength,
      WebsiteURL,

      _BPProtectedAddress,
      _BusinessPartner

}