I_BusPartRoleProcTempVH

@AbapCatalog.sqlViewName: 'IBPROLEPROCTVH'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck:  #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.resultSet.sizeCategory: #XS
@ObjectModel.representativeKey: 'BusinessPartnerRole'
@ObjectModel.dataCategory: #VALUE_HELP
@ClientHandling.algorithm : #SESSION_VARIABLE
@Search.searchable: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Value Help View for BP Role'
@Analytics.internalName:#LOCAL
@AbapCatalog.compiler.compareFilter:true
@Consumption.ranked: true 
define view I_BusPartRoleProcTempVH
  as select from I_BusinessPartnerRole as Role
    inner join   tb003a                as _RoleCategory on Role.RoleCategory = _RoleCategory.rolecategory
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BPRoleCategoryAllowList as _AllowList on Role.RoleCategory = _AllowList.RoleCategory
{
      @ObjectModel.text.association: '_BusinessPartnerRoleText'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BusinessPartnerRole,
  key cast( '1' as bu_type ) as BusinessPartnerCategory,
      @UI.hidden: true
      Role.RoleCategory      as RoleCategory,
      @Search.ranking: #LOW
      _BusinessPartnerRoleText
}
where
      _RoleCategory.xpers            = 'X'
  and _AllowList.BusinessPartnerRole is null

union select from I_BusinessPartnerRole as Role
  inner join      tb003a                as _RoleCategory on Role.RoleCategory = _RoleCategory.rolecategory
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
association [0..1] to I_BPRoleCategoryAllowList as _AllowList on Role.RoleCategory = _AllowList.RoleCategory
{
      @ObjectModel.text.association: '_BusinessPartnerRoleText'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BusinessPartnerRole,
  key cast( '2' as bu_type ) as BusinessPartnerCategory,
      @UI.hidden: true
      Role.RoleCategory      as RoleCategory,
      @Search.ranking: #LOW
      _BusinessPartnerRoleText
}
where
      _RoleCategory.xorg             = 'X'
  and _AllowList.BusinessPartnerRole is null

union select from I_BusinessPartnerRole as Role
  inner join      tb003a                as _RoleCategory on Role.RoleCategory = _RoleCategory.rolecategory
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
association [0..1] to I_BPRoleCategoryAllowList as _AllowList on Role.RoleCategory = _AllowList.RoleCategory
{
      @ObjectModel.text.association: '_BusinessPartnerRoleText'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BusinessPartnerRole,
  key cast( '3' as bu_type ) as BusinessPartnerCategory,
      @UI.hidden: true
      Role.RoleCategory      as RoleCategory,
      @Search.ranking: #LOW
      _BusinessPartnerRoleText
}
where
      _RoleCategory.xgroup           = 'X'
  and _AllowList.BusinessPartnerRole is null